////////////////////////////////////////////////////////////////////////////////
////////////////////////////////////////////////////////////////////////////////
// BOSSES                                                                     //
////////////////////////////////////////////////////////////////////////////////
////////////////////////////////////////////////////////////////////////////////

actor NinjaBoss : Ninja replaces FloatingSkull 42 
{
  SpawnID 41
  
  obituary "%o was sliced by a ninja."
  health 225
  speed 20
  
  states
  {
  Death:
    BSPI J 20 A_Scream
    BSPI K 7 A_NoBlocking
    BSPI LMN 7
    BSPI O 20
    BSPI O 20 A_BrainDie
    loop
  }
}

actor CrocRock replaces CacodemonBall
{
  SpawnID 64
  
  Game Doom
  SpawnID 126
  Radius 6
  Height 8
  Speed 36
  FastSpeed 36
  Damage 5
  DeathSound "skeleton/melee"
  Projectile
  +BLOODLESSIMPACT
  -NOGRAVITY
  
  States
  {
  Spawn:
    SSWV U 10
    loop
  Death:
    SSWV RST 5
    stop
  }
}

actor KillerCroc replaces PainElemental 71
{
  SpawnID 42
  
  spawnid 115
  health 1050
  radius 20
  height 63
  mass 400
  speed 10
  painchance 128
  seesound "knight/sight"
  painsound "pain/pain"
  deathsound "pain/death"
  Monster
  -COUNTKILL
  +FLOORCLIP
  
  states
  {
  Spawn:
    VILE A 10 A_Look
    loop
  See:
    VILE AABBCCDDEEFF 2 A_VileChase
    loop
  Melee:
    SKUL C 7
    SKUL C 7 A_SkelFist
    SKUL D 0
    goto See
  Pain:
    PAIN G 6
    PAIN G 6 A_Pain
    goto See
  Death:
    CPOS H 30 A_Scream
    CPOS I 5
    CPOS J 5 A_KeenDie
    CPOS KLM 5
    CPOS N -1
    stop
  Heal:
    VILE "[" 6
    VILE "\" 6 A_FaceTarget
    VILE "]" 10 A_HeadAttack
    Goto See
  }
}

actor TallyMan replaces SpiderMastermind 7
{
  SpawnID 43
  
  obituary "%o was filled full of lead by TallyMan."
  health 1200
  radius 24
  height 63
  mass 1000
  speed 12
  painchance 30
  seesound "spider/sight"
  attacksound "spider/attack"
  painsound "knight/pain"
  deathsound "vile/death" 
  Monster
  -COUNTKILL
  +FLOORCLIP
  +BOSS
  +NORADIUSDMG
  +DONTMORPH
  +MISSILEMORE
  
  states
  {
  Spawn:
    POSS A 10 A_Look
    loop
  See:
    POSS AABBCCDD 3 A_Chase
    loop
  Missile:
    SPID G 15 bright A_FaceTarget
    SPID HH 4 bright A_SPosAttack
    goto See
  Pain:
    POSS G 3
    POSS G 3 A_Pain
    goto See
  Death:
    TROO I 8
    TROO J 8 A_Scream
    TROO KL 6
    TROO M 20
    TROO M -1 A_BrainDie
    stop
  }
}

actor PenguinCopter replaces TechPillar 84
{
  SpawnID 44
  
  obituary "%o was shot by Penguin."
  health 1500
  radius 64
  height 83
  mass 1000
  speed 8
  painchance 15
  DeathSound "weapons/rocklx"
  Monster
  -COUNTKILL
  +FLOORCLIP
  +NOGRAVITY
  +FLOAT
  +NOBLOOD
  
  states
  {
  Spawn:
    SSWV A 10 A_Look
    loop
  See:
    SSWV A 2 A_PlaySound("vile/firecrkl")
    SSWV ABB 2 A_Chase
    loop
  Pain:
    SSWV A 1 A_Pain
    goto See
  Missile:
    SSWV A 2 bright A_FaceTarget
    CPOS F 2 bright A_SPosAttack
    SSWV A 4 bright A_SPosAttack
    CPOS F 2 bright A_SpidRefire
    goto Missile+1
  Death:
    SPID J 5 A_Scream
    SPID K 5 A_NoBlocking
    SPID LMNOPQR 5
    SPID S 60
    SPID S -1 A_BrainDie
    stop
  }
}

actor PenguinBoss2 replaces HangTLookingUp 77
{
  SpawnID 45
  
  obituary "%o was shot by The Penguin."
  health 1000
  radius 24
  height 183
  mass 1000000
  speed 0
  painchance 200
  PainSound "fatso/shotx"
  DeathSound "brain/spit"
  Monster
  -COUNTKILL
  +FLOORCLIP
  +NOBLOOD
  
  states
  {
  Spawn:
    BAL7 C 5 A_Look
    loop
  See:
    BAL7 C 5 A_Chase
    Loop
  Pain:
    BAL7 D 5 A_Pain
    BAL7 CECD 5
    Goto See
  Missile:
    SSWV H 5
    BBRN B 5 Bright A_SPosAttack
    SSWV H 5
    Goto See
  Death:
    BAL7 E 5 A_Scream
    BBRN A 5
	TBLU A 6 
	TBLU B 6 
	TBLU C 6 A_KeenDie
	TBLU D -1
    stop
  }
}

actor ScarecrowShotSmoke replaces RevenantTracerSmoke
{
  +NOBLOCKMAP
  +NOGRAVITY
  +NOTELEPORT
  
  RenderStyle Translucent 
  Alpha 0.8
  
  states
  {
  Spawn:
    POL5 A 10 A_Look
    loop
  See:
    FIRE CBC 6 A_SargAttack 
    CEYE ABC 6
    stop
  }
}

actor ScarecrowShot replaces RevenantTracer
{
  SpawnID 65
  
  Game Doom
  Radius 11
  Height 8
  Speed 10
  Damage 5
  Projectile 
  +BLOODLESSIMPACT
  +SEEKERMISSILE 
  +RANDOMIZE
  SeeSound "wolfss/sight"
  DeathSound "skeleton/attack"
  
  RenderStyle Translucent 
  Alpha 0.8
  
  States
  {
  Spawn:
    FATB AB 2 bright A_Tracer
    loop
  Death:
    FBXP A 8 bright
    FBXP B 6 bright
    FBXP C 4 bright
    stop
  }
}

actor Scarecrow replaces Revenant 66
{
  SpawnID 46
  
  obituary "%o couldn't evade a Scarecrow's poisonball."
  hitobituary "%o was scared to death of Scarecrow."
  health 1300
  radius 24
  height 63
  mass 500
  speed 10
  painchance 100
  seesound "skeleton/sight"
  painsound "knight/pain"
  deathsound "skeleton/death"
  Monster
  -COUNTKILL
  +FLOORCLIP
  +LONGMELEERANGE
  +MISSILEMORE
  
  states
  {
  Spawn:
    BOSS A 10 A_Look
    loop
  See:
    BOSS AABBCCDD 2 A_Chase
    loop
  Melee:
    SKEL G 0 A_FaceTarget
    SKEL G 6 A_SkelWhoosh
    SKEL H 6 A_FaceTarget
    SKEL I 6 A_SkelFist
    goto See
  Missile:
    SKEL J 0 A_FaceTarget
    SKEL J 10 A_FaceTarget
    SKEL K 10 A_SkelMissile
    SKEL K 10 A_FaceTarget
    goto See
  Pain:
    SKEL L 5
    SKEL L 5 A_Pain
    goto See
  Death:
    SKEL LM 7
    SKEL N 7 A_Scream
    SKEL Q -1 A_KeenDie
    loop
  }
}

actor TwoFaceRocket replaces BaronBall
{
  SpawnID 66
  
  Game Doom
  Radius 6
  Height 16
  Speed 15
  FastSpeed 20
  Damage 5
  SeeSound "baron/attack"
  DeathSound "weapons/rocklx"
  Projectile
  +BLOODLESSIMPACT
  +RANDOMIZE
  
  states
  {
  Spawn:
    BAL7 A 4 bright
    loop
  Death:
    MISL B 3 bright A_Explode(128)
    MISL CD 3 bright
    APBX AB 3 bright
    stop
  }
}

actor TwoFace replaces Cyberdemon 16
{
  SpawnID 47
  
  obituary "%o was splattered by a Two Face's rocket"
  health 1200
  radius 24
  height 63
  mass 1000
  speed 7
  painchance 128
  seesound "cyber/sight"
  painsound "cyber/pain"
  deathsound "keen/death"
  Monster
  -COUNTKILL
  +FLOORCLIP
  +BOSS
  +NORADIUSDMG
  +DONTMORPH
  +MISSILEMORE
  
  states
  {
  Spawn:
    CYBR A 10 A_Look
    loop
  See:
    CYBR AABBCCDD 3 A_Chase
    loop
  Melee:
    BOS2 G 15 A_SkelFist
    CYBR A 10 A_FaceTarget
  Missile:
    CYBR E 0 A_FaceTarget
    CYBR F 8 BRIGHT A_BruisAttack
    CYBR E 6 A_FaceTarget
    goto See
  Pain:
    CYBR G 10 A_Pain
    goto See
  Death:
    CYBR H 10
    CYBR I 10 A_Scream
    CYBR JKL 10
    CYBR M 10 A_NoBlocking
    CYBR NO 10
    CYBR P 30
    CYBR P -1 A_KeenDie
  }
}

actor TrickDart replaces FatShot
{
  SpawnID 67
  
  Game Doom
  Radius 6
  Height 8
  Speed 20
  FastSpeed 20
  Damage 3
  SeeSound "weapons/rocklf"
  DeathSound "weapons/plasmax"
  
  Projectile
  +BLOODLESSIMPACT
  
  states
  {
  Spawn:
    MANF A -1
    loop
  Death:
    PLAY UVW 8 BRIGHT
    stop
  }
}

actor Joker replaces ZombieMan 64
{
  SpawnID 48
  
  obituary "%o was shot by The Joker."
  health 800
  radius 24
  height 63
  mass 1000
  speed 8
  painchance 20
  seesound "pain/active"
  attacksound "weapons/pistol"
  painsound "vile/pain"
  deathsound "vile/death"
  Monster
  -COUNTKILL
  +FLOORCLIP
  
  states
  {
  Spawn:
    SPID A 10 A_Look
    loop
  See:
    SPID ABCDEF 3 A_Chase
    loop
  Missile:
    VILE GHIJK 6 A_FaceTarget
    VILE L 6 Bright A_VileAttack
    VILE KJIH 6 A_FaceTarget
    goto See
  Pain:
    VILE Q 5 A_Pain
    goto See
  Death:
    TNT1 A 1 A_NoBlocking
    TNT1 A 1 A_SpawnItem("Joker2",0,0,0,0)
    TNT1 A 1
	stop
  }
}

actor Joker2 2007 
{
  SpawnID 49
  
  obituary "%o was tricked by The Joker."
  health 800
  radius 24
  height 63
  mass 1000
  speed 8
  painchance 20
  seesound "pain/active"
  painsound "vile/pain"
  deathsound "vile/death"
  Monster
  -COUNTKILL
  +FLOORCLIP
  
  states
  {
  Spawn:
    SPID A 10 A_Look
    loop
  See:
    SPID ABCDEF 3 A_Chase
    loop
  Missile:
    FATT G 20 A_FaceTarget
    FATT H 0 A_FatAttack1
    FATT H 10 A_FatAttack2
    goto See
  Pain:
    VILE Q 5
    VILE Q 5 A_Pain
    goto See
  Death:
    KEEN AB 5
    KEEN C 5 A_Scream
    KEEN DE 5
    KEEN F -1 A_KeenDie
    stop
  }
}

actor Bane replaces BaronOfHell 3003 
{
  SpawnID 50
  
  obituary "%o was beat down by Bane."
  health 1400//was 140 changed final glove to be more powerful for DM/other uses
  radius 24
  height 64
  mass 500
  speed 15
  Damage 5
  painchance 150
  attacksound "skull/melee"
  painsound "knight/pain"
  deathsound "brain/cube"
  Monster
  -COUNTKILL
  +FLOORCLIP
  
  states
  {
  Spawn:
    SKEL A 10 A_Look
    loop
  See:
    CPOS R 8
    CPOS S 8 A_PlaySound("imp/death")
    CPOS T 23
    CPOS S 7
    CPOS R 7
    SKEL ABCDEF 4 A_Chase
    goto See+5
  Pain:
    SPID I 2
    SPID I 2 A_Pain
    goto See+5
  Melee:
    HEAD B 5 A_FaceTarget
    HEAD C 5 A_FaceTarget
    TROO G 6 A_SkelFist
    HEAD D 6 A_FaceTarget
    goto See+5
  Missile:
    HEAD B 10 A_FaceTarget
    TROO E 4 A_SkullAttack
    TROO F 25
    loop
  Death:
    BOSS I 8
    BOSS J 8 A_Scream
    BOSS KLMN 8
    BOSS O 50
    BOSS O 50 A_BrainDie
    loop
  }
}