////////////////////////////////////////////////////////////////////////////////
////////////////////////////////////////////////////////////////////////////////
// ENEMIES                                                                    //
////////////////////////////////////////////////////////////////////////////////
////////////////////////////////////////////////////////////////////////////////

actor BadBird replaces Candlestick 34
{
  SpawnID 11
  
  obituary "%o was bitten by a bird."
  health 10
  radius 16
  height 16
  mass 500
  speed 20
  painchance 0
  damage 3
  SeeSound "pain/sight"
  AttackSound "skull/melee"
  DeathSound "wolfss/death"
  Monster
  -COUNTKILL
  +NOGRAVITY
  +FLOAT
  
  states
  {
  Spawn:
    PAIN A 10 A_Look
    loop
  See:
    PAIN AABBCC 3 A_Chase
    SSWV C 6 A_Chase
    loop
  Missile:
    BOS2 F 10 A_FaceTarget
    BOS2 F 40 A_SkullAttack
    BOS2 FF 4 
    goto Missile+2
  Death:
    PAIN H 4 A_Scream
    PAIN IJK 4
    PAIN L 4 A_NoBlocking
    PAIN M -1
    stop
  }
}

actor Terrorist replaces HellKnight 3004
{
  SpawnID 12
  
  obituary "%o was shot by a Terrorist."
  health 40
  radius 24
  height 63
  mass 100
  speed 8
  painchance 200
  seesound "grunt/sight"
  attacksound "weapons/pistol"
  painsound "knight/pain"
  deathsound "grunt/death"
  Monster
  -COUNTKILL
  +FLOORCLIP
  
  states
  {
  Spawn:
    TROO A 10 A_Look
    loop
  See:
    TROO AABBCCDD 4 A_Chase
    goto See
  Pain:
    TROO H 3
    TROO H 3 A_Pain
    goto See
  Missile:
    POSS E 8 A_FaceTarget
    POSS F 8 bright A_PosAttack
    goto See
  Death:
    POSS H 5
    POSS I 5 A_Scream
    POSS J 5 A_NoBlocking
    POSS K 5
    POSS L -1
    loop
  }
}

actor TerroristGray : Terrorist replaces TechLamp2 86
{
  SpawnID 14
  
  health 30
  Translation 0
}

actor TerroristBrown : Terrorist replaces ShotgunGuy 36
{
  SpawnID 13
  
  states
  {
  Death:
    POSS H 5
    POSS I 5 A_Scream
    POSS J 5 A_NoBlocking
    POSS J 0 A_SpawnItemEx("BlueKey",0,0,0,0,0,0,0,0,0)
    POSS K 5
    POSS L -1
    loop
  }
  //DropItem "BlueKey" 255
  Translation 1
}

actor TerroristRed : Terrorist replaces TallGreenColumn 30
{
  SpawnID 15
  
  health 25
  Translation 2
}

actor ShotgunThief replaces Fatso 9
{
  SpawnID 16
  
  obituary "%o was shot by a shotgunner."
  health 30
  radius 24
  height 63
  mass 100
  speed 8
  painchance 170
  seesound "imp/active"
  painsound "vile/pain"
  deathsound "chainguy/death2"
  Monster
  -COUNTKILL
  +FLOORCLIP
  
  states
  {
  Spawn:
    SPOS A 10 A_Look
    loop
  See:
    SPOS AABBCCDD 2 A_Chase
    loop
  Missile:
    SPOS E 10 A_FaceTarget
    SPOS F 10 bright A_SPosAttack
    SPOS E 10
    goto See
  Pain:
    SPOS G 3
    SPOS G 3 A_Pain
    goto See
  Death:
    SPOS H 5
    SPOS I 5 A_Scream
    SPOS J 5 A_NoBlocking
    SPOS K 5
    SPOS L -1
    stop
  }
}

actor GangWarShotgunThief : ShotgunThief replaces RocketBox 2046
{
  SpawnID 17
  
  health 100
  painchance 130
  
  states
  {
  See:
    SPOS E 10
    goto missile
  }
}

actor CheungShuriken replaces DoomImpBall
{
  SpawnID 61
  
  Game Doom
  Radius 6
  Height 8
  Speed 10
  FastSpeed 20
  Damage 3
  Projectile
  +BLOODLESSIMPACT
  +RANDOMIZE
  SeeSound "skull/melee"
  DeathSound "imp/shotx"
  
  States
  {
  Spawn:
    BAL1 AB 4 bright
    loop
  Death:
    BAL1 CDE 6 bright
    stop
  }
}

actor Cheung replaces DoomImp 3001
{
  SpawnID 18
  
  obituary "%o was killed by Cheung."
  health 60
  radius 24
  height 63
  mass 100
  speed 10
  painchance 200
  seesound "imp/sight"
  painsound "imp/pain"
  deathsound "baby/death"
  Monster
  -COUNTKILL
  +FLOORCLIP
  
  states
  {
  Spawn:
    CPOS A 10 A_Look
    loop
  See:
    CPOS AABBCCDD 3 A_Chase
    loop
  Melee:
  Missile:
    BOSS EF 8 A_FaceTarget
    BOSS G 6 A_TroopAttack
    goto See
  Pain:
    CPOS G 6
    CPOS G 6 A_Pain
    goto See
  Death:
    TROO N 4
    TROO O 4 A_Scream
    TROO P 4
    TROO Q 4 A_NoBlocking
    TROO RST 4
	TROO U -1
    loop
  }
}

actor GangWarCheung : Cheung 2010
{
  SpawnID 19
  
  health 120
  painchance 150
  
  states
  {
  See:
    BOSS E 1
    goto missile
  }
}

ACTOR StrakeGreen replaces Demon 3002
{
  SpawnID 20
  
  Game Doom
  obituary "%o was stabbed by Strake."
  SpawnID 8
  Health 150
  PainChance 180
  Speed 10
  Radius 24
  Height 56
  Mass 400
  Monster
  -COUNTKILL
  +FLOORCLIP
  +FASTER 
  +FASTMELEE
  SeeSound "demon/sight"
  AttackSound "demon/melee"
  painsound "caco/death"
  DeathSound "demon/death"
  
  States
  {
  Spawn:
    SARG A 10 A_Look
    Loop
  See:
    SARG AABBCCDD 2 A_Chase
    Loop
  Melee:
    SARG EF 8 A_FaceTarget
    SARG G 8 A_SargAttack
    Goto See
  Pain:
    SARG H 2
    SARG H 2 A_Pain
    Goto See
  Death:
    SARG I 8
    SARG J 8 A_Scream
    SARG K 4
    SARG L 4 A_NoBlocking
    SARG M 4
    SARG N -1
    Stop
  }
}

ACTOR StrakeGray : StrakeGreen replaces TechLamp 85
{
  SpawnID 21
  
  Health 130
  Translation 0
}

actor PenguinRobot replaces Column 2028
{
  SpawnID 22
  
  Game Doom
  Health 30
  Speed 11
  Radius 16
  Height 45
  Mass 200
  Monster
  -COUNTKILL
  +FLOORCLIP
  +NOBLOOD
  +OLDRADIUSDMG
  
  DeathSound "weapons/rocklx"
  States
  {
  Spawn:
    HEAD A 10 A_Look
    Loop
  See:
    BOSS H 5 A_Chase
    HEAD A 5 A_Chase
	Loop
  Melee:
  Death:
    BEXP A 2 Bright A_Pain
    BEXP B 5 Bright
	BEXP C 4 Bright A_Scream
	BEXP D 4 Bright A_Explode(128)
	BEXP E 4 Bright
	SPOS TU 4 Bright
    Stop
  }
}

actor Ninja replaces Arachnotron 68 
{
  SpawnID 23
  
  obituary "%o was sliced by a ninja."
  health 150
  radius 24
  height 63
  mass 1000
  speed 8
  painchance 128
  seesound "baby/sight"
  painsound "grunt/pain"
  deathsound "baby/death"
  Monster
  -COUNTKILL
  +FLOORCLIP
  
  states
  {
  Spawn:
    BSPI C 10 A_Look
    loop
  See:
    BSPI A 20
    BSPI A 3 A_SargAttack
    BSPI ABBCC 3 A_Chase
    BSPI D 0 A_Chase
    BSPI D 3 A_PlaySound("baby/walk")
    BSPI D 3 A_SargAttack
    BSPI EEFF 3 A_Chase
    goto See+1
  Pain:
    BSPI I 3
    BSPI I 3 A_Pain
    goto See
  Death:
    BSPI J 20 A_Scream
    BSPI K 7 A_NoBlocking
    BSPI LMN 7
    BSPI O -1
    stop
  }
}

actor Flame replaces ArachnotronPlasma
{
  SpawnID 62
  
  Game Doom
  Radius 13
  Height 8
  Speed 25
  Damage 2
  SeeSound "wolfss/sight"
  Projectile
  +BLOODLESSIMPACT
  RenderStyle Add 
  Alpha 0.8
  
  Projectile
  +BLOODLESSIMPACT
  states
  {
  Spawn:
    TLP2 ABCD 4
    stop
  Death:
    FIRE FGH 5 BRIGHT
    stop
  }
}

actor FlameMan replaces Archvile 69 
{
  SpawnID 24
  
  obituary "%o was burned."
  health 350
  radius 24
  height 63
  mass 1000
  speed 10
  painchance 20
  seesound "baby/active"
  attacksound "baby/pain"
  painsound "baby/pain"
  deathsound "grunt/death"
  Monster
  -COUNTKILL
  +FLOORCLIP
  
  states
  {
  Spawn:
    BOS2 A 10 A_Look
    loop
  See:
    BOS2 ABCD 4 A_Chase
    goto See
  Pain:
    BOS2 H 2
    BOS2 H 2 A_Pain
    goto See
  Missile:
    BSPI G 9 A_FaceTarget
    BSPI H 9
    BSPI G 9
    BOS2 A 3 Bright A_Chase
    BOS2 A 3 Bright A_BspiAttack
    BOS2 B 3 Bright A_Chase
    BOS2 B 3 Bright A_BspiAttack
    BOS2 C 3 Bright A_Chase
    BOS2 C 3 Bright A_BspiAttack
    BOS2 D 3 Bright A_Chase
    BOS2 D 3 Bright A_BspiAttack
    BSPI G 4 Bright A_SpidRefire
    goto Missile+3
  Death:
    BOS2 I 6
    BOS2 J 6 A_Scream
    BOS2 K 6
    BOS2 L 6 A_NoBlocking
    BOS2 MN 6
    BOS2 O -1
    stop
  }
}

actor ExplosiveShell replaces ArchvileFire
{
  obituary "%o shot by a sniper."
  +NOGRAVITY
  states
  {
  Spawn:
    POL5 A 10 A_Look
    loop
  See:
    TGRN A 0 BRIGHT A_PlaySound("cyber/hoof")
    TGRN A 3 BRIGHT A_SargAttack 
    BON2 BC 3 BRIGHT
    FSKU ABC 3 BRIGHT
    TGRN B 3 BRIGHT
    stop
  }
}

ACTOR Sniper replaces Spectre 58
{
  SpawnID 25
  
  Game Doom
  obituary "%o shot by a sniper."
  Health 60
  PainChance 100
  Speed 0
  Radius 24
  Height 63
  Mass 10000
  Monster
  -COUNTKILL
  +FLOORCLIP
  AttackSound "demon/melee"
  painsound "knight/pain"
  DeathSound "grunt/death2"
  
  States
  {
  Spawn:
    BOSF D 10 A_Look
    Loop
  See:
    BOSF D 2 A_Chase
    Loop
  Missile:
    BOSF D 8 A_VileTarget
    CPOS P 2 Bright A_SargAttack
    CPOS P 2 Bright
    SSWV EFG 4
    CPOS Q 4
    SSWV E 4
    Goto See
  Pain:
    CPOS O 10 A_Pain
    SSWV E 4
    Goto See
  Death:
    RSKU A 4 A_Scream
    RSKU B 4
    APLS A 4
    BOSF C 4
    SKUL K -1 A_NoBlocking
    Stop
  }
}

actor Clown replaces ShortRedTorch 57 
{
  SpawnID 26
  
  obituary "%o was tricked by a clown."
  health 300
  radius 24
  height 63
  mass 200
  speed 10
  painchance 150
  seesound "skeleton/active"
  painsound "vile/pain"
  deathsound "keen/pain"
  Monster
  -COUNTKILL
  +FLOORCLIP
  
  states
  {
  Spawn:
    SSWV D 3 A_Look
    loop
  See:
    FATT EF 4 A_Chase
    SSWV D 4 A_Chase
    CPOS E 4 A_Chase
    loop
  Pain:
    VILE M 5 A_Pain
    goto See
  Missile:
    SKUL B 8 A_FaceTarget
    VILE O 8 A_FaceTarget
    VILE P 8 A_FatAttack2
    goto See
  Death:
    PLAY O 7
    PLAY P 7 A_Scream
    PLAY Q 7 A_NoBlocking
    PLAY RS 7
    PLAY T -1
    stop
  }
}

actor SuperClown : Clown replaces Meat3 51
{
  SpawnID 27
  
  Health 400
  Speed 11
  PainChance 120
  Mass 250
  
  States
  {
  Death:
    PLAY O 7 A_KeenDie
    PLAY P 7 A_Scream
    PLAY Q 7 A_NoBlocking
    PLAY RS 7
    PLAY T -1
    stop
  }
}

actor ZekeMolotov replaces LostSoul 3006
{
  SpawnID 63
  
  Radius 22
  Height 1
  Speed 35
  FastSpeed 35
  Damage 8
  SeeSound "skull/melee"
  AttackSound "skull/melee"
  DeathSound "knight/death"
  Projectile
  +BLOODLESSIMPACT
  -NOGRAVITY
  
  States
  {
  Spawn:
    COL3 AA 2 BRIGHT
    COL1 A 6 BRIGHT
    BAL2 ABABA 6 BRIGHT
    BROK A 6 BRIGHT
    stop
  Death:
    COL3 AA 2 BRIGHT
    COL1 A 6 BRIGHT
    BAL2 ABABA 6 BRIGHT
    BROK A 6 BRIGHT
    stop
  }
}

actor Zeke replaces HeartColumn 67
{
  SpawnID 28
  
  obituary "%o was flamed by Zeke."
  health 350
  radius 30
  height 63
  mass 1000
  speed 9
  painchance 30
  seesound "fatso/death"
  painsound "caco/death"
  Monster
  -COUNTKILL
  +FLOORCLIP
  
  states
  {
  Spawn:
    FATT A 10 A_Look
    loop
  See:
    FATT AABBCCDD 3 A_Chase
    loop
  Pain:
    FATT J 3
    FATT J 3 A_Pain
    goto See
  Missile:
    PAIN E 15 bright A_FaceTarget
    PAIN F 4 bright A_SargAttack
    PAIN D 4 bright A_CustomMissile(ZekeMolotov)
    goto See
  Death:
    FATT K 6
    FATT L 6 A_Scream
    FATT M 6 A_NoBlocking
    FATT NOPQRS 6
    FATT T -1 A_BossDeath
    stop
  }
}

actor RocketMan replaces BossTarget 87
{
  SpawnID 29
  
  obituary "%o was shot by a RocketMan."
  health 300
  radius 24
  height 63
  mass 1000
  speed 10
  painchance 25
  painsound "knight/pain"
  deathsound "grunt/death"
  Monster
  -COUNTKILL
  +FLOORCLIP
  +NOBLOOD
  +NOGRAVITY
  +FLOAT
  
  states
  {
  Spawn:
    SKUL E 3 A_Look
    MISL A 3 A_Look
    loop
  See:
    SKUL E 3 A_Chase
    MISL A 3 A_Hoof
    loop
  Pain:
    VILE N 4 A_Pain
    goto See
  Missile:
    BOS2 E 4 bright A_CPosAttack
    FATT I 4 bright A_CPosRefire
    goto Missile
  Death:
    HDB3 A 7
    BOSF A 7 A_Scream
    BOSF B 7 A_NoBlocking
    KEEN G 7
    KEEN M -1
    stop
  }
}

actor EyeBall replaces Meat4 52
{
  SpawnID 30
  
  obituary "%o died ... somehow."
  health 500
  radius 13
  height 56
  mass 100
  speed 8
  painchance 100
  DeathSound "vile/active"
  Monster
  -COUNTKILL
  +NOGRAVITY
  +FLOAT
  +AMBUSH//makes the eyes come out better
  
  states
  {
  Spawn:
    BFS1 B 10 A_Look
    loop
  See:
    BFS1 B 5
    KEEN IJ 5
    KEEN K 45
    KEEN J 4
    KEEN I 4
    BFS1 B 4
    KEEN I 4 Bright
    KEEN J 4 Bright
    KEEN K 4 Bright A_Chase
    Goto See+9
  Pain:
    KEEN JI 4 Bright
    BFS1 B 4 Bright
    KEEN IJ 4 Bright
    Goto See+9
  Missile:
    KEEN L 5 Bright
    EYEB A 5 Bright A_CyberAttack
    KEEN L 5 Bright
    Goto See+9
  Death:
    BFE2 A 4 Bright A_Scream
    PLSE DE 6 Bright
	BFE2 B 6 Bright A_KeenDie
    stop
  }
}