actor DangerWrapWep : MegaBuster 10085
{
Weapon.AmmoUse 2
Weapon.AmmoGive 28
Weapon.SlotNumber 5
Obituary "%o was burst by %k's Danger Wrap."
Inventory.Pickupmessage "Power up! Danger Wrap!"
weapon.ammotype "DangerWrapAmmo"
inventory.pickupsound "weapon/weaponup"
+WEAPON.AMMO_OPTIONAL
inventory.icon "DWRASI"
Scale 2.0
States
{
Spawn:
WEA3 L 1
loop
Ready:
DWRA I 0 ACS_ExecuteAlways(998,0,70)
DWRA I 1 A_WeaponReady
Goto Ready+1
Deselect:
TNT1 AAAAAAAAAAAAAAAAAAAAAA 0 A_Lower
DWRA I 1 A_Lower
Loop
Select:
TNT1 AAAAAAAAAAAAAAAAAAAAAA 0 A_Raise
DWRA I 1 A_Raise
Loop
Fire:
DWRA I 0 A_JumpIfNoAmmo("NoAmmo")
DWRA I 0 A_PlaySoundEx("weapon/wrapfire","Weapon")
DWRA I 0 A_FireCustomMissile("DangerWrap",0,1,8,0)
DWRA JK 6
DWRA I 13
DWRA I 0 A_Refire
Goto Ready+1
NoAmmo:
DWRA I 1 ACS_Execute(979,0)
Goto Ready+1
}
}

actor DangerWrapAmmo : Ammo
{
inventory.amount 1
inventory.maxamount 28
}


actor DangerWrap
{
PROJECTILE
Radius 20
Height 12
scale 2.5
speed 15
States
{
Spawn:
DWRA A 0
DWRA ABC 3
DWRA A 0 A_GiveInventory("Clip",1)
Goto Fly
Fly:
DWRA DE 5 ThrustThingZ(0,2,0,1)
loop
Death:
DWRA F 2 A_ChangeFlag("NOGRAVITY",0)
DWRA F 1 A_JumpIf(z-floorz==0,"SpawnMine")
NoMine:
DWRA F 1 A_JumpIf(z-floorz==0,"XDeath")
loop
Crash:
XDeath:
NAPA A 0 A_Stop
NAPA A 0 A_SpawnItemEx("WrapExplosion")
stop
SpawnMine:
TNT1 A 1 A_SpawnItemEx("DangerWrapMine")
stop
}
}

actor WrapExplosion
{
+NOGRAVITY
-SOLID
+MISSILE
Radius 1
Height 1
scale 2.5
speed 0
States
{
Spawn:
NAPA A 0
NAPA A 0 A_PlaySoundEx("weapon/wrapexplode", "Weapon")
NAPA D 0 A_Explode(40, 128, 0)
NAPA EFGHIJKLMNOPQRS 1
stop
}
}

actor DangerWrapMine
{
PROJECTILE
+NOCLIP
-NOGRAVITY
Radius 32
Height 12
scale 2.5
damage (1)
speed 0
reactiontime 200
States
{
Spawn:
DWRA F 0// A_ChangeFlag("MISSILE",0)
DWRA F 5 
DWRA F 0 A_ChangeFlag("NOCLIP",0)
Goto Mine
Mine:
DWRA G 1 A_CountDown
DWRA G 0 A_JumpIfInTargetInventory("IsDead",1,"Death")
loop
Death:
NAPA A 0 A_Stop
NAPA A 0 A_ChangeFlag("NOGRAVITY",1)
NAPA A 0 A_PlaySoundEx("weapon/wrapexplode", "Weapon")
NAPA D 0 A_Explode(40, 128, 0)
NAPA DEFGHIJKLMNOPQRS 1
stop
}
}