ACTOR MBossEye : BossEye replaces BossEye
{
  DamageFactor "Control", 0
  States
  {
  Spawn:
    SSWV A 5 A_Look
	SSWV A 5
    Loop
  }
}

ACTOR MBossBrain : BossBrain replaces BossBrain
{
  DamageFactor "Control", 0
  DamageFactor "MarineDamage", 1
  DamageFactor "ImpBallDamage", 0
  DamageFactor "ZombiesDamage", 0
  DamageFactor "CacoDamage", 0
  DamageFactor "SkelDamage", 0
  DamageFactor "FatsoDamage", 0
  DamageFactor "KnightDamage", 0
  DamageFactor "ArachDamage", 0
  DamageFactor "viledamage", 0
  States
  {
  Spawn:
    BBRN A 1 
    loop
  }
}

ACTOR MExplosiveBarrel : ExplosiveBarrel replaces ExplosiveBarrel
{
 PainChance "Control", 255
 DamageFactor "Control", 1
 States
 {
  Spawn:
    BAR1 AB 6
    BAR1 A 0 Thing_SetSpecial (0,226,409,0,health)
  See:
    BAR1 ABAB 6
    BAR1 A 0 A_JumpIf (special != 226,1) 
    loop	
    BAR1 A 0 Thing_SetSpecial (0,226,409,0,health)
    goto see
  Death:
    BEXP A 5 BRIGHT
    BEXP B 5 BRIGHT A_Scream
    BEXP C 5 BRIGHT
    BEXP D 5 BRIGHT A_Explode
    BEXP E 10 BRIGHT
    BEXP E 1050 BRIGHT A_BarrelDestroy
    BEXP E 5 A_Respawn
    Wait
  Death.Control:
    TNT1 A 0
    TNT1 A 0 A_NoBlocking
    TNT1 A 5 ACS_Execute(427,0,1)
    TNT1 A 1050 BRIGHT A_BarrelDestroy
    TNT1 A 5 A_Respawn
    Wait
 }
}
ACTOR MExplosiveBarrel2 : MExplosiveBarrel
{
 States
 {
  Death:
    BEXP A 5 BRIGHT
    BEXP B 5 BRIGHT A_Scream
    BEXP C 5 BRIGHT
    BEXP D 5 BRIGHT A_Explode
    BEXP E 10 BRIGHT
    TNT1 A 0 Thing_Remove (0)
    Stop
  Death.Control:
    TNT1 A 0
    TNT1 A 0 A_NoBlocking
    TNT1 A 20 ACS_Execute(427,0,1)
    TNT1 A 0 Thing_Remove (0)
    Stop
 }
}

ACTOR MExplosiveBarrel3 : MExplosiveBarrel2
{
  radius 5
  height 30
  -SOLID
  -SHOOTABLE
  DamageType "CybRLDamage"
 States
 {
  Spawn:
    BAR1 AB 0
    goto Death
  See:
    BAR1 AB 0
    goto Death
  Death:
    BEXP A 5 BRIGHT A_SpawnItemEx ("MDeathGhost",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION,0)
    BEXP B 5 BRIGHT A_Scream
    BEXP C 5 BRIGHT
    BEXP D 5 BRIGHT A_Explode
    BEXP E 10 BRIGHT
    TNT1 A 0 Thing_Remove (0)
    Stop
 }
}