ACTOR GreenFiend : BullFiend
{ 
Monster
Health 280
Speed 12
PainChance 80
BloodColor "Green" 
Scale 1.15
+MISSILEMORE
+QUICKTORETALIATE
+THRUSPECIES
+DONTHARMSPECIES
Species "Fiends"
DropItem "LifeEssence", 125
DropItem "ArmorBonusMax", 125
DropItem "DemonAmmo", 128, 120
SeeSound "blooddemon/sight"
PainSound "blooddemon/pain"
DeathSound "blooddemon/death"
ActiveSound "blooddemon/active"
AttackSound "cyberfiend/melee"
Obituary "%o was pierced by a Infection Fiend."
HitObituary "Infection Fiend will hide the remnants for not giving the other Pinkys."
Tag "\c[q6]Infection Fiend\c-"
States 
	{ 
	Spawn: 
		GDEM A 10 A_Look
		Loop
	See:
		TNT1 A 0 A_SetTranslucent(1,0)
		GDEM AABB 2 A_Chase
		TNT1 A 0 A_PlaySound("blooddemon/walk",CHAN_BODY)
		GDEM CCDD 2 A_Chase
		TNT1 A 0 A_PlaySound("blooddemon/walk",CHAN_BODY)
		Loop
	Melee: 
		TNT1 A 0 A_SetTranslucent(1,0)
		GDEM EF 5 A_FaceTarget
		GDEM G 4 A_MeleeAttack
		GDEM E 5 A_FaceTarget
		Goto See
	Missile:
		TNT1 A 0 A_SetTranslucent(1,0)
		TNT1 A 0 A_Jump(128,"Lunge")
	Normal:
		GDEM GE 7 A_FaceTarget		
		GDEM F 6 Bright A_CustomMissile("ToxicBall", 32, 0, 0)
		GDEM E 5
		Goto See
	Lunge:
		TNT1 A 0 A_JumpIfCloser(250,1)
		Goto See
		TNT1 A 0 A_SetTranslucent(1,0)
		TNT1 A 0 A_PlaySound("cyberfiend/melee")
		GDEM EF 7 A_FaceTarget
		TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,1)
		TNT1 A 0 ThrustThingZ(0,20,0,1)
		GDEM F 2 A_Recoil(-28)
		GDEM F 3 A_CustomMissile("PinkyLunge",18,0,0,CMF_AIMDIRECTION)
		GDEM G 6
		GDEM G 2 A_ScaleVelocity(0.2)
		TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,0)
		GDEM G 1 A_ScaleVelocity(0)
		Goto See
	Pain: 
		TNT1 A 0 A_SetTranslucent(1,0)
		TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,0)
		GDEM H 4 A_Pain
		Goto See
	XDeath:
	Death:
		TNT1 A 0 A_SetTranslucent(1,0)
		GDEM I 5 A_ChangeFlag(SLIDESONWALLS,0)
		GDEM J 5 A_Scream
		GDEM K 4 A_SpawnItemEx("GreenGibbedGenerator",0,0,0,0,0,0,0,128,0)
		GDEM L 4 A_NoBlocking
		GDEM M 4 A_SpawnItem("BodyCrash",0,0,0,0)
		GDEM N 63000 CanRaise 
		Stop
	Raise: 
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
		GDEM NMLKJI 5 
		Goto See 
	}
}