//Watcher created by Ben2k9/Virtue

ACTOR DarkGMinion : HereticImp 
{
  Health 110
  Radius 16
  Height 36
  Mass 50
  Speed 15
  Painchance 50
  scale 1.2
  Monster
  +FLOAT
  +NOGRAVITY
  +SPAWNFLOAT
  +DONTOVERLAP
  +MISSILEMORE
  +DONTHURTSPECIES
  Species "Nobles"
  DamageFactor "Fire", 0
  SeeSound "himp/sight"
  AttackSound "himp/attack"
  PainSound "himp/pain"
  DeathSound "himp/death"
  ActiveSound "himp/active"
  Obituary "%o was burnt by a Dark Gargoyle."
  HitObituary "%o was slashed by a Dark Gargoyle."
  Tag "Dark Gargoyle"
  States
  {
  Spawn:
    WATC ABCB 10 A_Look
    Loop
  See:
    WATC AABBCCBB 3 A_Chase
    Loop
  Melee:
    WATC DE 4 BRIGHT A_FaceTarget
    WATC F 4 BRIGHT A_CustomMeleeAttack(random[ImpMeAttack](7,14), "himp/attack")
    WATC "[\]" 4 BRIGHT A_FaceTarget
    WATC ] 0 BRIGHT A_CustomMeleeAttack(random[ImpMeAttack](7,14), "himp/attack")     
    Goto See
  Missile:
    TNT1 A 0 A_Jump(148,"Mainattack")
    WATC E 0 BRIGHT A_jump(100,"beastball")
  Mainattack:	
	WATC DE 4 BRIGHT A_FaceTarget
    WATC F 4 BRIGHT A_CustomComboAttack("NewImpBall", 28, 14, "himp/leaderattack")	
    WATC "[\]" 4 BRIGHT A_FaceTarget
    WATC ] 0 BRIGHT A_CustomComboAttack("NewImpBall", 28, -14, "himp/leaderattack")	
    WATC DE 4 BRIGHT A_FaceTarget
    WATC F 4 BRIGHT A_CustomComboAttack("NewImpBall", 28, 14, "himp/leaderattack")    
    Goto See
  Beastball:
    WAT2 DE 6 BRIGHT A_FaceTarget
    WAT2 F 6 Bright A_Custommissile ("SSatyrBall", 27, 0, 0)
    TNT1 A 0 A_Jump(128, "Beastball")	
    Goto See
  Pain:
    WATC G 3
    WATC G 3 A_Pain
    Goto See
  Death:
    TNT1 A 0 A_TakeInventory("SuccubusToken",1,0,AAPTR_MASTER)
    WATC G 4 A_ImpDeath
    WATC H 5
    Wait
  XDeath:
    TNT1 A 0 A_TakeInventory("SuccubusToken",1,0,AAPTR_MASTER)
    WATC S 5 A_ImpXDeath1
    WATC TU 5
    WATC V 5 A_Gravity
    WATC W 5 
    Wait
  Crash:
    WATC I 7 A_ImpExplode
    WATC J 7 A_Scream
    WATC K 7
    WATC L -1
    Stop
  XCrash:
    WATC X 7
    WATC Y 7
    WATC Z -1
    Stop
  Ice:	
    TNT1 A 0 A_TakeInventory("SuccubusToken",1,0,AAPTR_MASTER)
	WATC G 5 A_GenericFreezeDeath
	WATC G 1 A_FreezeDeathChunks
	wait
  }
}

Actor HereticImpBall2 : HereticImpBall
{
   States
   {
   	Spawn:
		HIB1 ABC 6 Bright
		Loop
	Death:
		HIB1 DEFG 5 Bright
		Stop
   }
}

Actor Beastball2 : BeastBall
{
   States
   {
   	Spawn:
		FRB1 AABBCC 2 A_SpawnItemEx("Puffy", random2[BeastPuff]()*0.015625, random2[BeastPuff]()*0.015625, random2[BeastPuff]()*0.015625, 
									0,0,0,0,SXF_ABSOLUTEPOSITION, 64)
		Loop
	Death:
		HIB2 DEFGH 4
		Stop
	}
}
