ACTOR ShadowAnniImp : Imp
{
  Scale 1.1
  BloodColor "cf 00 b0"
  Health 850
  PainChance 45
  PainChance "SoulToxic", 20
  PainChance "FatFlamer", 20
  PainChance "FiendFire", 20
  PainChance "Explosion", 90
  +DONTHARMCLASS
  +DONTHARMSPECIES
  +DONTHURTSPECIES
  +MISSILEEVENMORE
  +FASTMELEE
  +AVOIDMELEE
  SeeSound "cimp/sight"
  PainSound "cimp/pain"
  DeathSound "cimp/death"
  ActiveSound "cimp/active"
  MeleeSound "weapons/fistwiff"
  MeleeDamage 10
  DamageFactor "Cyber10K", 0.5
  DamageFactor "PDTBFG", 0.6
  DamageFactor "PDTBFGTracer", 0.9
  DropItem "LifeEssence" 256
  DropItem "ArmorBonusMax" 256
  DropItem "BossLifeEssence" 128 25
  DropItem "BossArmorBonusMax" 128 1
  DropItem "DemonAmmo" 128 30
  DropItem "DemonAmmo" 128 30
  DropItem "Missile" 64 5
  DropItem "MissileBox" 32 10
  DropItem "Demon Tech Rifle" 100 1
  DropItem "Railgun " 85 1
  DropItem "PhaseRifle" 30 1
  DropItem "Rocket Launcher" 30 1
  DropItem "Grenade Launcher" 15 1
  Tag "Shadow Annihilator Imp"
  Obituary "%o was put down by an Shadow Annihilator Imp."
  HitObituary "%o was smacked by an Shadow Annihilator Imp's cannon."
  States
  {
  Spawn:
    SAHI A 10 A_Look
	SRIM A 10 A_Look
    Loop
  See:
    SAHI AABB 3 A_Chase
	TNT1 A 0 A_SpawnItem("HumanishStep",0,0,0,0)
	SAHI CCDD 3 A_Chase
	TNT1 A 0 A_SpawnItem("HumanishStep",0,0,0,0)
    Loop
  Pause:
	SAHI E 10
	Goto See
  Pause2:
	SAHI G 10
	Goto See
  Melee: 
    SAHI EF 5 A_FaceTarget
    SAHI G 4 A_MeleeAttack
	SAHI FE 5 A_FaceTarget
    Goto See 
  Lunge:
	TNT1 A 0 A_JumpIfCloser(300,1)
	Goto See
	TNT1 A 0 A_PlaySound("weapons/fistwiff")
	SAHI EF 7 A_FaceTarget
	TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,1)
	TNT1 A 0 ThrustThingZ(0,25,0,1)
	SAHI G 2 A_Recoil(-30)
	SAHI G 3 A_CustomMissile("PinkyLunge",18,0,0,CMF_AIMDIRECTION)
	SAHI G 6 
	SAHI F 2 A_ScaleVelocity(0.2)
	TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,0)
	SAHI E 1 A_ScaleVelocity(0)
	Goto See
  Missile:
    TNT1 A 0 A_Jump(128,"DtechRifle")
	TNT1 A 0 A_Jump(50, "Railgun")
	TNT1 A 0 A_Jump(70, "PhaseRifle")
    TNT1 A 0 A_JumpIfCloser(200, "Nades")
    TNT1 A 0 A_JumpIfCloser(250, "Lunge")
    SAHI E 6 A_FaceTarget
    SAHI W 10 BRIGHT A_CustomMissile("PhaseCyberRocket")
	SAHI F 5
	SAHI G 6 A_FaceTarget
    SAHI V 10 BRIGHT A_CustomMissile("PhaseCyberRocket")
	SAHI G 5
	TNT1 A 0 A_Jump(64,"Homing")
    Goto See
  DtechRifle:
    SAHI G 10 A_FaceTarget
	TNT1 A 0 A_CustomMissile("DTFDemonTechProjectile",36,0,Random(150,-150)/100.00,0)
	SAHI G 3 Bright A_PlaySoundEx("weapons/demontechfire","Weapon")
	TNT1 A 0 A_CustomMissile("DTFDemonTechProjectile",36,0,Random(150,-150)/100.00,0)
	SAHI G 3 Bright A_PlaySoundEx("weapons/demontechfire","Weapon")
	TNT1 A 0 A_CustomMissile("DTFDemonTechProjectile",36,0,Random(150,-150)/100.00,0)
	SAHI G 3 Bright A_PlaySoundEx("weapons/demontechfire","Weapon")
	TNT1 A 0 A_Jump(62,"Pause")
    SAHI G 10 A_FaceTarget
	TNT1 A 0 A_Jump(64,"Pause2")
    TNT1 A 0 A_CPosRefire
    Goto DtechRifle+1
  Railgun:
    TNT1 A 0 A_PlaySound("weapons/rgcharge")
	SAHI EEE 10 A_FaceTarget
	SAHI E 10 Bright A_FaceTarget
	SAHI E 10 Bright A_CustomMissile("PhaseCyberRail",36,0)
	TNT1 A 0 A_Jump(128, "SecondRailgun")
	Goto See
  SecondRailgun:
    TNT1 A 0 A_PlaySound("weapons/rgcharge")
	SAHI GGG 10 A_FaceTarget
	SAHI G 10 Bright A_FaceTarget
	SAHI G 10 Bright A_CustomMissile("PhaseCyberRail",36,0)
	Goto See  
  PhaseRifle:
    SAHI E 10 A_FaceTarget
	TNT1 A 0 A_CustomMissile("EnemyPhaseDTProjectile",36,0,Random(150,-150)/100.00,0)
	SAHI E 3 Bright A_PlaySoundEx("weapons/demontechfire","Weapon")
	TNT1 A 0 A_CustomMissile("EnemyPhaseDTProjectile",36,0,Random(150,-150)/100.00,0)
	SAHI E 3 Bright A_PlaySoundEx("weapons/demontechfire","Weapon")
	TNT1 A 0 A_CustomMissile("EnemyPhaseDTProjectile",36,0,Random(150,-150)/100.00,0)
	SAHI E 3 Bright A_PlaySoundEx("weapons/demontechfire","Weapon")
	TNT1 A 0 A_Jump(62,"Pause")
    SAHI E 10 A_FaceTarget
	TNT1 A 0 A_Jump(64,"Pause2")
    TNT1 A 0 A_CPosRefire
	Goto PhaseRifle+1
  Homing:
    SAHI E 6 A_FaceTarget
    SAHI W 10 BRIGHT A_CustomMissile("PhaseCyberHomer")
	SAHI F 15
	SAHI G 6 A_FaceTarget
    SAHI V 10 BRIGHT A_CustomMissile("PhaseCyberHomer")
	SAHI G 5
    Goto See
  Nades:
    SAHI E 6 A_FaceTarget
	TNT1 A 0 A_PlaySound("Weapons/GrenadeFire")
    SAHI W 10 BRIGHT A_CustomMissile("CyberImpGrenade")
	SAHI F 5
	SAHI G 6 A_FaceTarget
	TNT1 A 0 A_PlaySound("Weapons/GrenadeFire")
    SAHI V 10 BRIGHT A_CustomMissile("CyberImpGrenade")
	SAHI G 5
    Goto See
  Pain:
    SAHI H 2
    SAHI H 2 A_Pain
    Goto See
  Death:
    SAHI I 8
    SAHI J 8 A_Scream
    SAHI K 6
    SAHI L 6 A_NoBlocking
	SAHI M 0 A_SpawnItem("BodyCrash",0,0,0,0)
    SAHI M -1
    Stop
  XDeath:
    SAHI N 5 A_playsound("weapons/rocklx")
    SAHI O 5 A_XScream
	SAHI P 0 A_SpawnItemEx("GibbedGenerator",0,0,0,0,0,0,0,128,0)
	TNT1 A 0 A_SpawnItemEx("CyberImpDeathRocket",0,0,28)
	SAHI P 5 A_Explode(80,100)
    SAHI Q 5 A_NoBlocking
    SAHI RST 5
    SAHI U -1
    Stop
  Raise:
    TNT1 A 0
	TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
    SAHI ML 8
    SAHI KJI 6
    Goto See
  }
}

Actor EnemyPhaseDTProjectile : PhaseDTProjectile
{
    Damage 20
}	