actor LightningSuccubus : SuccubusBase
{
	Obituary "%o was very shocked by the ThunderWing Succubus"
	Tag "ThunderWing Succubus"
	health 600
	MONSTER
    +NOTARGET
    +FLOORCLIP
    +DONTHURTSPECIES
    +NOGRAVITY
    +FLOAT
    DropItem "LifeEssence" 75
    DropItem "ArmorBonusMax" 75
    Species "Nobles"
	States
	{
	Spawn: 
		SUF4 ABCDBA 10 Bright A_Look
		Loop 
    See: 
		SUF4 AABBCCDDAABBCCDD 2 BRIGHT A_Chase
		Loop
	Missile:
	   TNT1 A 0 A_Jump(85, "Lightning")
	   TNT1 A 0 A_Jump(70, "Explosive")
	   TNT1 A 0 A_Jump(55, "Spread")
	   TNT1 A 0 A_Jump(40, "Seeker")
	   TNT1 A 0 A_Jump(40, "SpreadExplosive")
	Lightning:
	   SUF4 E 8 Bright A_FaceTarget
       SUF4 F 8 Bright A_FaceTarget
       SUF4 G 1 Bright A_Custommissile ("SuccubusLigProjectile", 27, 0, 0) 
       SUF4 E 8 Bright A_FaceTarget
       SUF4 F 8 Bright A_FaceTarget
       SUF4 G 1 Bright A_Custommissile ("SuccubusLigProjectile", 27, 0, 0) 
	   Goto See
	Seeker:
       SUF4 E 8 Bright A_FaceTarget
       SUF4 F 8 Bright A_FaceTarget
       SUF4 G 1 Bright A_Custommissile ("SeekerLightningSuc", 27, 0, 0)
	   Goto See
	Explosive:
       SUF4 E 8 Bright A_FaceTarget
       SUF4 F 8 Bright A_FaceTarget
       SUF4 G 1 Bright A_Custommissile ("LightningBallSuc", 27, 0, 0)
	   Goto See
    SpreadExplosive:	   
	   SUF4 E 8 Bright A_FaceTarget
       SUF4 F 8 Bright A_FaceTarget
	   TNT1 A 0 Bright A_Custommissile ("LightningBallSuc", 27, 0, -20)
	   TNT1 A 0 Bright A_Custommissile ("LightningBallSuc", 27, 0, 20)
       SUF4 G 1 Bright A_Custommissile ("LightningBallSuc", 27, 0, 0)
	   Goto See
    Spread:
       SUF4 E 8 Bright A_FaceTarget
       SUF4 F 8 Bright A_FaceTarget
	   TNT1 A 0 Bright A_Custommissile ("SuccubusLigProjectile", 27, 0, -30)
	   TNT1 A 0 Bright A_Custommissile ("SuccubusLigProjectile", 27, 0, -20)
	   TNT1 A 0 Bright A_Custommissile ("SuccubusLigProjectile", 27, 0, -10)
	   TNT1 A 0 Bright A_Custommissile ("SuccubusLigProjectile", 27, 0, 10)
	   TNT1 A 0 Bright A_Custommissile ("SuccubusLigProjectile", 27, 0, 20)
	   TNT1 A 0 Bright A_Custommissile ("SuccubusLigProjectile", 27, 0, 30)
       SUF4 G 4 Bright A_Custommissile ("SuccubusLigProjectile", 27, 0, 0)
       Goto See	   
	Pain: 
       SUC4 L 2 Bright 
       SUC4 L 2 Bright A_Pain 
       Goto See
    Death: 
       SUC4 M 7 Bright
       SUC4 N 7 Bright A_Scream 
       SUC4 O 7 Bright
       SUC4 P 7  A_NoBlocking 
       SUC4 QRST 7
       SUC4 U -1 
       Stop 
	Raise:
		SUC4 UTSRQ 8 Bright
		SUC4 P 0 A_PlaySoundEx("pyr/resurrected", 3)
		SUC4 PONM 8 Bright
		Goto See 
 	}
}

Actor SuccubusLigProjectile : FastProjectile 
{
	Projectile
	Height 8
	Radius 8
	Speed 18
	Damage 10
	SeeSound "weapons/gntini"
	DeathSound "weapons/devzap"
	States
	{
	Spawn:
	    FX03 CDEF 4 Bright 
		Loop
	Death:
        FX03 HIJKLM 6 Bright
        Stop		
    }
}

Actor SeekerLightningSuc
{
    +SEEKERMissile
	Projectile
	Speed 14
	Damage 8
	Height 8
	Radius 8
	SeeSound "weapons/gntini"
	DeathSound "weapons/devzap"
	States
	{
	Spawn:
	    FX00 CDEF 4 Bright A_SeekerMissile(16, 6)
		Loop
	Death:
        FX00 HIJKLM 6 Bright
        Stop		
    }
}

Actor LightningBallSuc : LegAvaBall2
{
    Damage 4
    ExplosionDamage 34
	ExplosionRadius 16
}