actor AirShooterBoss : MegaBuster 20036
{
Weapon.AmmoUse 2
Weapon.AmmoGive 28
Weapon.SlotNumber 4
Obituary "%o was blown away by %k's Air Shooter."
weapon.ammotype "Can'tDefeatAmmo"
inventory.pickupsound "weapon/weaponup"
+WEAPON.AMMO_OPTIONAL
Scale 2.0
States
{
Spawn:
TNT1 A 0
stop
Ready:
AIRA A 0 ACS_ExecuteAlways(998,0,102)
AIRA A 0 A_JumpIfInventory("Can'tDefeatAmmo",2,"Ready2")
AIRA A 10 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
AIRA A 0 A_GiveInventory("Can'tDefeatAmmo",1)
Goto Ready+1
Ready2:
AIRA A 0 A_JumpIfInventory("Can'tDefeatAmmo",4,"Ready3")
AIRA A 10 A_WeaponReady(WRF_NOSECONDARY|WRF_NOSWITCH)
AIRA A 0 A_GiveInventory("Can'tDefeatAmmo",1)
loop
Ready3:
AIRA A 10 A_WeaponReady(WRF_NOSWITCH)
AIRA A 0 A_GiveInventory("Can'tDefeatAmmo",1)
loop
Deselect:
TNT1 AAAAAAAAAAAAAAAAAAAAAA 0 A_Lower
AIRA A 1 A_Lower
Loop
Select:
TNT1 AAAAAAAAAAAAAAAAAAAAAA 0 A_Raise
AIRA A 1 A_Raise
Loop
Fire:
AIRA A 0 A_JumpIfNoAmmo("NoAmmo")
AIRA A 0 A_PlaySoundEx("weapon/airshooter","Weapon")
AIRA A 0 A_FireCustomMissile("AirShot2",-15,0,8,0)
AIRA A 0 A_FireCustomMissile("AirShot2",15,0,8,0)
AIRA A 0 A_FireCustomMissile("AirShot2",0,1,8,0)
AIRA BC 6
AIRA A 7
AIRA A 0 A_Refire
Goto Ready+1
AltFire:
AIRA A 0 A_JumpIfInventory("Can'tDefeatAmmo",4,"AirWall")
goto Ready+1
AirWall:
//AIRA A 0 A_PlaySoundEx("weapon/airshooter","Weapon")
AIRA A 0 A_PlaySoundEx("weapon/airwall","Auto")
AIRA A 0 A_SpawnItemEx("AirWall",0,0,32,15,0,0)
AIRA A 0 A_SpawnItemEx("AirWall",0,0,32,15,random(-16,-16),random(0,0))
AIRA A 0 A_SpawnItemEx("AirWall",0,0,32,15,random(-16,-16),random(0,0))
AIRA A 0 A_SpawnItemEx("AirWall",0,0,32,15,random(-32,32),random(-8,16))
AIRA A 0 A_SpawnItemEx("AirWall",0,0,32,15,random(-32,32),random(-8,16))
AIRA A 0 A_SpawnItemEx("AirWall",0,0,32,15,random(-64,64),random(-16,32))
AIRA A 0 A_SpawnItemEx("AirWall",0,0,32,15,random(-64,64),random(-16,32))
AIRA A 0 A_TakeInventory("Can'tDefeatAmmo",4)
AIRA BC 6
AIRA A 7
AIRA A 0 A_Refire
Goto Ready+1

NoAmmo:
AIRA A 0
//AIRA A 1 ACS_Execute(979,0)
Goto Ready+1
}
}

actor Can'tDefeatAmmo : Ammo
{
inventory.amount 1
inventory.maxamount 28
}

actor AirWind
{
PROJECTILE
Radius 32
Height 24
scale 2.5
speed 40
States
{
Spawn:
AIWI ABCD 3 A_RadiusThrust (740000, 1, 0)
loop
}
}

actor AirWall : actor
{
PROJECTILE
Radius 6
Height 7
scale 2.5
damage (5)
damagetype "Air"
speed 0
States
{
Spawn:
AIRS AABBCC 1 A_Recoil(3)
AIRS A 0 A_Stop
AIRS ABC 2
AIRS A 0 A_SpawnItemEx("AirWall2")
stop
}
}

actor AirWall2 : actor
{
PROJECTILE
Radius 6
Height 7
scale 2.5
damage (20)
damagetype "Air"
speed 0
States
{
Spawn:
AIRS AABBCC 1 A_Recoil(-4)
loop
}
}