actor TimeSlowWep : Megabuster 20043
{
Weapon.AmmoUse 1
Weapon.AmmoGive 48
Weapon.SlotNumber 6
Obituary "%o was frozen in time by %k's Time Slow."
Inventory.Pickupmessage "Power up! Time Slow!"
weapon.ammotype "SlowAmmo"
inventory.pickupsound "weapon/weaponup"
+WEAPON.AMMO_OPTIONAL
Inventory.Icon "TIMMI"
Scale 2.0 
states
{
Spawn:
SLOT A 1
loop
Ready:
SLOT B 0 ACS_ExecuteAlways (998,0,120)
SLOT B 0 ACS_ExecuteAlways (991,0,120)
SLOT B 1 A_WeaponReady
goto Ready+2
Deselect:
TNT1 AAAAAAAAAAAAAAAAAAAAAA 0 A_Lower
SLOT B 1 A_Lower
Loop
Select:
TNT1 AAAAAAAAAAAAAAAAAAAAAA 0 A_Raise
SLOT B 1 A_Raise
Loop
Fire:
SLOT B 0 A_JumpIfNoAmmo("NoAmmo")
SLOT B 0 A_PlaySoundEx("weapon/timeshot","Weapon")
SLOT B 0 A_FireCustomMissile("TimeArrow",random(-7,-5),1,8,0)
SLOT B 0 A_FireCustomMissile("TimeArrow",random(5,7),0,8,0)
SLOT B 0 A_TakeInventory("TimeCharge",999)
SLOT CD 5
SLOT B 0 A_Refire
goto Ready+2
Fire1:
SLOT B 0 A_JumpIfInventory("SlowAmmo", 20, "Fire2")
Goto Fire
Fire2:
SLOT B 0 A_JumpIfNoAmmo("NoAmmo")
SLOT B 0 A_TakeInventory("SlowAmmo",20)
SLOT B 1 A_GiveInventory("TimeQuick",1)
SLOT B 0 A_TakeInventory("TimeCharge",999)
SLOT JKLMN 2
SLOT K 0 A_PlaySoundEx("weapon/slow","Weapon")
SLOT L 0 ACS_Execute(976,0)
SLOT L 0 A_FireCustomMissile("TimeSlow",0,0,8,0)
TNT1 A 8
goto Ready+2
Hold:
SLOT B 0 A_JumpIfNoAmmo("NoAmmo")
SLOT B 0 A_JumpIfInventory("PowerTime",1,"Fire")
SLOT B 0 A_JumpIfInventory("TimeCharge",30,"Charge2")
SLOT B 1 A_JumpIfInventory("TimeCharge",5,"Charge")
SLOT B 1 A_GiveInventory("TimeCharge",1)
SLOT B 0 A_Refire
goto Ready+2
Charge:
SLOT B 0 A_JumpIfInventory("TimeCharge",6,"Charge1")
SLOT B 0 A_PlaySoundEx("weapon/ccharge","Weapon")
SLOT B 0 A_GiveInventory("TimeCharge",1)
SLOT B 2
goto Charge1
Charge1:
SLOT B 0 A_JumpIfNoAmmo("NoAmmo")
SLOT B 0 A_JumpIfInventory("TimeCharge",30,"Charge2")
SLOT H 1 ACS_ExecuteAlways (991,0,121)
SLOT B 1 ACS_ExecuteAlways (991,0,120)
SLOT B 0 A_GiveInventory("TimeCharge",1)
SLOT B 0 A_Refire
goto Fire
Charge2:
SLOT B 0 ACS_ExecuteAlways (991,0,122)
SLOT F 1
SLOT B 1 ACS_ExecuteAlways (991,0,123)
SLOT G 1
SLOT F 1 ACS_ExecuteAlways (991,0,120)
//SLOT B 0 A_PlaySoundEx("weapon/chargeloop","Weapon")
TNT1 H 0 A_PlaySoundEx("weapon/coilcharge", "Weapon")
SLOT B 0 ACS_ExecuteAlways(974,0)
SLOT B 0 A_Refire
goto Fire1
NoAmmo: 
SLOT B 1 ACS_Execute(979,0)
goto Ready+2
}
}

actor SlowAmmo : Ammo
{
inventory.amount 1
inventory.maxamount 48
}

actor TimeArrow
{
PROJECTILE
Damage (13)
Height 7
Radius 6
+FORCEXYBILLBOARD
//+RIPPER
Scale 2.5
speed 32
damagetype "TimeArrow"
States
{
Spawn:
SLOT EEI 3 //ACS_Execute(979,0)
loop
}
}

actor TimeCharge : Inventory
{
inventory.amount 1
inventory.maxamount 30
States
{
Spawn:
TNT1 A 1
loop
}
}

actor TimeSlow
{
-SOLID
+NOGRAVITY
PROJECTILE
damage 0
radius 1
height 1
damagetype "Slow"
States
{
Spawn:
TNT1 A 0
TNT1 A 1 A_Explode(15, 500,0)
stop
}
}

actor TimeQuick : PowerupGiver
{
inventory.maxamount 0
powerup.duration 245
powerup.color "00 00 00", 0.0
powerup.type "PowerTime"
+INVENTORY.AUTOACTIVATE
+INVENTORY.ALWAYSPICKUP
states
{
Pickup:
TNT1 A 175 
stop
}
}


actor PowerTime : PowerFrightener
{
Inventory.Icon "TIMICON"
Speed 1.0
}

actor SlowSound : CustomInventory
{
inventory.amount 1
inventory.maxamount 1
States
{
Spawn:
TNT1 A 1
loop
Pickup:
TNT1 A 0
TNT1 A 1 A_PlaySoundEx("weapon/slow","weapon")
TNT1 A 0 A_GiveInventory("Slowed",1)
stop
}
}

actor BossSlowed : PowerupGiver
{
Speed 0.75
powerup.duration 350
powerup.type "PowerSlow"
+INVENTORY.AUTOACTIVATE
+INVENTORY.ALWAYSPICKUP
states
{
Pickup:
TNT1 A 0 
TNT1 A 175
stop
}
}

actor Slowed : PowerupGiver
{
Speed 0.67
powerup.duration 175
powerup.type "PowerSlow"
+INVENTORY.AUTOACTIVATE
+INVENTORY.ALWAYSPICKUP
states
{
Pickup:
TNT1 A 0 

TNT1 A 175
stop
}
}

actor PowerSlow : PowerSpeed
{
Speed 0.67
Powerup.Color "55 00 55", 0.4
}