ACTOR CyberBaron : BaronOfHell
{ 
Health 1500
PainChance 50
MeleeDamage 8
Scale 1.1
Obituary "%o was blown apart by a Cyber-Baron of Hell."
HitObituary "%o got smacked by a Cyber-Baron of Hell."
SeeSound "cbaron/sight" 
PainSound "cbaron/pain"
DeathSound "cbaron/death"
MeleeSound "baron/melee"
ActiveSound "cbaron/active"
DamageFactor "NobleComet", 0.0
DropItem "LifeEssence" 150
DropItem "ArmorBonusMax" 150
DropItem "Assault Shotgun" 128
Species "Nobles"
BloodColor "Green"
+MISSILEMORE
+DONTHURTSPECIES
+FASTMELEE
  States 
  { 
  Spawn: 
    CBO2 A 7 A_Look
    Loop 
  See:
    CBO2 AABB 3 A_Chase
    TNT1 A 0 A_SpawnItem("HoofStep",0,0,0,0)
    CBO2 CCDD 3 A_Chase
    TNT1 A 0 A_Playsound("monster/bruwlk")
    Loop
  Pause:
	CBO2 E 10
	Goto See
  Missile:
    TNT1 A 0 A_Jump(128,"BurstBall","LargeBall","Rocket")
  Normal:
	TNT1 A 0 A_JumpifCloser(200,"SSG")
    CBO2 E 8 A_FaceTarget
	CBO2 E 6 A_FaceTarget
	TNT1 A 0 A_SpawnItemEx("ShellCasing", 0, 12, 36, Random(2, 6), 0, Random(1, 3), Random(-80, -90), 128)
	TNT1 AAA 0 A_CustomMissile("ProjectileBullet",40,0,Random(-1000,1000)/100.00,0)
	TNT1 A 0 A_CustomBulletAttack(22.5, 18.3, 4, Random(1,5)*3, "CyNoblePuff")
	CBO2 F 2 Bright A_PlaySoundEx("AShotgun/Fire","Weapon")
    TNT1 A 0 A_Jump(48,"Pause")
    TNT1 A 0 A_SpidRefire
	Goto Normal+2
  SSG:
    CBO2 E 8 A_FaceTarget
	CBO2 E 12 A_FaceTarget
	TNT1 A 0 A_SpawnItemEx("ShellCasing", 0, 12, 36, Random(2, 6), 0, Random(1, 3), Random(-80, -90), 128)
	TNT1 AAAAAAAA 0 A_CustomMissile("ProjectileBullet",40,0,Random(-1000,1000)/100.00,0)
	TNT1 A 0 A_CustomBulletAttack(18, 12, 10, Random(1,4)*3, "CyNoblePuff")
	CBO2 F 4 Bright A_PlaySoundEx("weapons/sshotf","Weapon")
    TNT1 A 0 A_Jump(128,"Pause")
	CBO2 E 12
    TNT1 A 0 A_SpidRefire
	Goto Normal
  BurstBall:
	CBO2 PQ 7 A_FaceTarget 
	CBO2 R 1 Bright A_CustomMissile("CyNobleBall", 32, 0, 0)		
	TNT1 A 0 A_CustomMissile("CyNobleBall", 32, 0, 6)
	CBO2 R 5 Bright A_CustomMissile("CyNobleBall", 32, 0, -6)
	TNT1 A 0 A_Jump(87,"LargeBall","Rocket")
	Goto See
  LargeBall:
  	CBO2 PQ 7 A_FaceTarget
	CBO2 R 6 Bright A_CustomMissile("DukeBall2", 32, 0, 0)
  Rocket:
    TNT1 A 0 A_Jump(128,"Missiles")
    CBO2 E 14 A_FaceTarget
    CBO2 F 8 Bright A_CustomMissile("CyNobleRocket",32,0,0,0)
    CBO2 E 10 A_FaceTarget
    CBO2 F 8 Bright A_CustomMissile("CyNobleRocket",32,0,0,0)
    CBO2 E 10 A_FaceTarget
    CBO2 F 8 Bright A_CustomMissile("CyNobleRocket",32,0,0,0)
    CBO2 E 10
    Goto See
  Missiles:
    CBO2 E 14 A_FaceTarget
    CBO2 F 8 Bright A_CustomMissile("BruiserMissile",32,0,0,0)
    CBO2 E 10 A_FaceTarget
    CBO2 F 8 Bright A_CustomMissile("BruiserMissile",32,0,0,0)
    CBO2 E 10 A_FaceTarget
    CBO2 F 8 Bright A_CustomMissile("BruiserMissile",32,0,0,0)
    CBO2 E 10
    Goto See
  Melee:
    CBO2 PQ 7 A_FaceTarget
    CBO2 R 7 A_MeleeAttack
    Goto See
  Pain: 
    TNT1 A 0 A_Jump(87,"PainMissile")
    CBO2 H 4 A_Pain
    Goto See
  PainMissile:
    CBO2 H 4 A_Pain
    Goto Missile	
  Death:
    CBO2 I 20 A_Scream
	TNT1 AA 0 A_SpawnItemEx("GreenGibbedGenerator",0,0,0,0,0,0,0,128,0)	
	CBO2 JJJKKK 2 Bright A_CustomMissile ("Kaboom5", Random(10,50), 0, random(0,360), 2, random(0,360))
	TNT1 AA 0 A_SpawnItemEx("GreenGibbedGenerator",0,0,0,0,0,0,0,128,0)
    TNT1 AAAA 0 A_CustomMissile("SmokeFX", Random(30,60), 0, random(0,360), 2, random(0,360))	
    CBO2 L 4 Bright A_NoBlocking
    CBO2 MN 3 Bright
    CBO2 O -1
    Stop
  Raise:
  	TNT1 A 0
	TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
    CBO2 N 5
	CBO2 MLKJI 5
	Goto See
    } 
}