ACTOR Mechtre : BullFiend 17552
{ 
//$Category Monsters/DUST
//$Sprite MCTRA1
//$Title "Mechtre"
  Renderstyle Normal
  Health 200
  Speed 14
  MaxTargetRange 350
  DropItem "LifeEssence" 105
  DropItem "ArmorBonusMax" 105
  SeeSound "mechtre/sight"
  PainSound "mechtre/pain"
  DeathSound "mechtre/death"
  ActiveSound "mechtre/active"
  AttackSound "mechtre/attack"
  Obituary "%o was shocked by a Mechtre."
  HitObituary "%o was shocked by a Mechtre."
  States 
  { 
  Spawn:
	MCTR A 12 A_Look
	Loop
  See:
	MCTR AAAAA 1 A_FadeOut(0.2,0)
  See2:
	MCTR AABB 2 A_Chase
	TNT1 A 0 A_PlaySound("blooddemon/walk")
	MCTR CCDD 2 A_Chase
	TNT1 A 0 A_PlaySound("blooddemon/walk")
	Loop 
  Melee: 
	TNT1 A 0 A_FaceTarget
	MCTR EEEEE 1 A_FadeIn(0.2)
	MCTR EF 5 A_FaceTarget
	MCTR G 4 A_MeleeAttack
	TNT1 A 0 A_FaceTarget
	MCTR EEEEE 1 A_FadeOut(0.2,0)
	Goto See2
  Missile:
	TNT1 A 0 A_JumpIfCloser(350,1)
	Goto See
	TNT1 A 0 A_PlaySound("mechtre/attack")
	TNT1 A 0 A_FaceTarget
	MCTR EEEEE 1 A_FadeIn(0.2)
	MCTR E 2
	MCTR F 7 A_FaceTarget
	TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,1)
	TNT1 A 0 ThrustThingZ(0,20,0,1)
	MCTR F 2 A_Recoil(-28)
	MCTR F 3 A_CustomMissile("PinkyLunge",18,0,0,CMF_AIMDIRECTION)
	MCTR G 6
	MCTR G 2 A_ScaleVelocity(0.2)
	TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,0)
	TNT1 A 0 A_ScaleVelocity(0)
	MCTR GGGGG 1 A_FadeOut(0.2,0)
	Goto See2
  Pain: 
	TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,0)
	TNT1 A 0 A_SetTranslucent(1.0)
	TNT1 A 0 A_Pain
	MCTR HHHHH 1 A_FadeOut(0.2,0)
	Goto See2
  Death:
	TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,0)
	MCTR I 5 A_SetTranslucent(1.0)
	MCTR J 5 A_Scream
	MCTR K 4
	MCTR L 4 A_NoBlocking     
	MCTR M 4 A_SpawnItem("BodyCrash",0,0,0,0)
	MCTR N -1 
	Stop
  XDeath:
	TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,0)
	TNT1 A 0 A_SetTranslucent(1.0)
	MCTX A 3 A_XScream
	MCTX B 3 A_SpawnItemEx("GibbedGenerator",0,0,0,0,0,0,0,128,0)
	MCTX C 3 A_NoBlocking
	MCTX D 3 A_SpawnItem("BodyCrash",0,0,0,0)
	MCTX EFG 3
	MCTX H -1 
	Stop
  Raise: 
	TNT1 A 0
	TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
	MCTR NMLKJI 5 
	Goto See  
	}
}