Actor RepeaterZombie 17580
{
//$Category Monsters/DUST
//$Sprite REPZA1
//$Title "Repeater Zombie"
  Monster
  Health 200
  Height 56
  Radius 20
  Speed 8
  PainChance 30
  Painchance "Mine", 128
  +FLOORCLIP
  +QUICKTORETALIATE
  DropItem "PortableMedkit", 200, 1
  DropItem "HealthFlask", 250, 2
  DropItem "ArmorPlate", 200, 1
  DropItem "AmmoPack", 100, 2
  DropItem "HandGrenadeAmmo", 100, 1
  DropItem "MineAmmo", 100, 1
  DropItem "CellPack", 200, 100
  DropItem "PlasmaRepeater", 32
  SeeSound "Grunt/Sight"
  ActiveSound "Grunt/Active"
  PainSound "Grunt/Pain"
  DeathSound "Grunt/Death"
  Obituary "%o was charred by a zombie with a Plasma Repeater."
  Tag "Repeater Zombie"
  States
  {
  Spawn:
	REPZ A 10 A_Look
	Loop
  Idle:
	TNT1 A 0 A_JumpIfInventory("RepeaterZombieFiring",1,"SpinDown")
	TNT1 A 0 A_ChangeFlag(NOPAIN,0)
	REPZ A 10 A_Look
	Loop
  See:
	TNT1 A 0 A_JumpIfInventory("RepeaterZombieFiring",1,"SpinDown")
	TNT1 A 0 A_ChangeFlag(NOPAIN,0)
	REPZ AB 4 A_Chase
    TNT1 A 0 A_SpawnItem("FootStep",0,0,0,0)
	REPZ CD 4 A_Chase
    TNT1 A 0 A_SpawnItem("FootStep",0,0,0,0)
	Loop 
  Missile:
	TNT1 A 0 A_ChangeFlag(NOPAIN,1)
	TNT1 A 0 A_GiveInventory("RepeaterZombieFiring",1)
	TNT1 A 0 A_PlaySound("PlasmaRepeater/Spin",7)
	REPZ EEFFEEFFEF 3 A_FaceTarget
  Normal:
	REPZ G 1 Bright A_CustomMissile("ZombieRepeaterPlasma",32,0,random(-8,8))
	REPZ G 1 A_FaceTarget
	REPZ H 1 Bright A_CustomMissile("ZombieRepeaterPlasma",32,0,random(-8,8))
	REPZ H 1 A_FaceTarget
	TNT1 A 0 A_Monsterrefire(36,"See")
	Loop
  SpinDown:
	TNT1 A 0 A_PlaySound("PlasmaRepeater/Down",7)
	TNT1 A 0 A_TakeInventory("RepeaterZombieFiring",1)
	REPZ EFEEFF 3
	Goto See
  Pain:
	TNT1 A 0 A_StopSound(7)
	REPZ I 3
	REPZ I 3 A_Pain 
	Goto See 
  Death:
	TNT1 A 0
	TNT1 A 0 A_StopSound(7)
	REPZ I 4
	REPZ J 5
	REPZ K 5 A_Scream 
	REPZ L 5 A_Fall
	REPZ M 5
	REPZ N -1
	Stop
  XDeath:
	TNT1 A 0
	TNT1 A 0 A_StopSound(7)
	REPZ O 5
	TNT1 A 0 A_SpawnItemEx("GibbedGenerator",0,0,30)
	REPZ P 5 A_XScream
	REPZ Q 5
	REPZ R 5 A_Fall
	REPZ STUV 5
	REPZ W -1
	Stop
  Raise:
	TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
	REPZ NMLKJI 5
	Goto See
	} 
}

Actor RepeaterZombieFiring : Inventory { Inventory.MaxAmount 1 }

Actor ZombieRepeaterPlasma : OverseerPlasma
{
  Damagetype "Normal"
}