ACTOR LaserSpider
{
Monster
Health 850
Height 64
Radius 52
Mass 600
Speed 5
Scale 1.2
Bloodcolor "Black"
Reactiontime 25
Painchance "Mine", 128
MaxtargetRange 4096
PainChance 45
+FLOORCLIP
+BOSSDEATH
+AVOIDMELEE
+MISSILEMORE
+DONTHARMSPECIES
Species "BabySpiders"
Damagetype "Baby15K"
Damagefactor "Acid", 3.8
//No Infighting
DamageFactor "Baby15K", 0.0
DropItem "BossLifeEssence", 196, 100
DropItem "HEMBossArmorBonusMax35", 196
DropItem "LaserCannon", 96
SeeSound "CGunSpider/Sight"
PainSound "monsters/fusionitepain"
DeathSound "CGunSpider/Death"
AttackSound "Null"
Obituary "%o was scorched by a Laser Arachnotron."
Tag "\c[i7]Laser Arachnotron\c-"
States
	{
	Spawn:
		LSPI A 10 A_Look
		Loop
	See:
		LSPI A 1 A_BabyMetal
		LSPI AAAAA 1 A_Chase("","")
		TNT1 A 0 A_Jump(8,"MissileD1")
	See1:
		LSPI BBBB 1 A_Chase("","")
		TNT1 A 0 A_Jump(3,"MissileD2")
	See2:
		LSPI CCCC 1 A_Chase("","")
		TNT1 A 0 A_Jump(3,"MissileD3")
	See3:
		LSPI D 1 A_BabyMetal
		LSPI DDDD 1 A_Chase("","")
		TNT1 A 0 A_Jump(3,"MissileD4")
	See4:
		LSPI EEEE 1 A_Chase("","")
		TNT1 A 0 A_Jump(3,"MissileD5")
	See5:
		LSPI FFFFF 1 A_Chase("","")
		TNT1 A 0 A_Jump(80,"MissileD6")
		Goto See
	MissileD1:
		TNT1 A 0 A_JumpIfTargetInLOS("Missile")
		GoTo See1
	MissileD2:
		TNT1 A 0 A_JumpIfTargetInLOS("Missile")
		GoTo See2
	MissileD3:
		TNT1 A 0 A_JumpIfTargetInLOS("Missile")
		GoTo See3
	MissileD4:
		TNT1 A 0 A_JumpIfTargetInLOS("Missile")
		GoTo See4
	MissileD5:
		TNT1 A 0 A_JumpIfTargetInLOS("Missile")
		GoTo See5
	MissileD6:
		TNT1 A 0 A_JumpIfTargetInLOS("Missile")
		GoTo See
	Missile:
		TNT1 A 0 A_PlaySound("monsters/darkmasterwind",CHAN_AUTO)
		LSPI AAAAA 2 A_FaceTarget(45)
	MissileLoop: //because rapid fire railguns are fun
		TNT1 A 0 A_FaceTarget
		TNT1 A 0 Bright A_PlaySound("monsters/darkmasterwind2",CHAN_AUTO)
		TNT1 A 0 A_CustomMissile("SpecOpsLaser",29,0,random(-4,4),0)
		LSPI G 2 Bright A_PlaySound("monsters/fusionfire",CHAN_WEAPON)
		LSPI GG 1 Bright A_FaceTarget
		TNT1 A 0 A_CustomMissile("SpecOpsLaser",29,0,random(-4,4),0)
		LSPI H 2 Bright A_PlaySound("monsters/fusionfire",CHAN_WEAPON)
		LSPI HH 1 Bright A_FaceTarget
		TNT1 A 0 A_Jump(8,"See")
		TNT1 A 0 A_SpidRefire
		Loop
	Pain:
		TNT1 A 0 A_Jump(61,"PainMissile")
		LSPI I 12 A_Pain
		Goto See
	PainMissile:
		LSPI I 12 A_Pain
		Goto Missile	
	Death:
		LSPI I 20 A_Scream
		LSPI J 6 A_KillChildren
		TNT1 AA 0 A_SpawnItemEx("BlackGibbedGenerator",0,0,0,0,0,0,0,128,0)
		LSPI KKKKK 2 Bright A_CustomMissile("Kaboom2",random(20,40),random(10,-10),random(0,360),2,random(0,360))
		TNT1 AAAA 0 A_CustomMissile("SmokeFX2",random(20,40),0,random(0,360),2,random(0,360))
		LSPI L 6 A_Fall
		TNT1 A 0 A_RemoveChildren
		LSPI MN 6
		LSPI O 6 A_KillMaster
		LSPI P 63000 CanRaise
		Stop
	Raise:
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
		LSPI PONMLKJ 5
		Goto See+1
	}
}

ACTOR RailgunImpactSpiderPuff
{
Decal None
+RIPPER
+NOBOSSRIP
+NOGRAVITY
+NOBLOCKMAP
+RANDOMIZE
+THRUSPECIES
+MTHRUSPECIES
+PUFFGETSOWNER
+NODAMAGETHRUST
Damagetype "Baby15K"
States
	{
	Spawn:
		TNT1 A 4 Bright
		Stop
	}
}

ACTOR RailgunImpactSpider : FastProjectile
{
Radius 1
Height 1
Speed 800
Decal "RedPlasmaScorch"
Damage (0)
+RIPPER
+NOBOSSRIP
+RANDOMIZE
+THRUSPECIES
+MTHRUSPECIES
+DONTHARMSPECIES
States
	{
	Spawn:
		TNT1 A 1 Bright
		Loop
	Death:
		TNT1 A 0 Bright
		TNT1 A 0 Bright A_SpawnItem("RedParticleSpawner")
		TNT1 A 0 Bright A_SpawnItem("LaserSpidFlare")
		TNT1 A 0 Bright A_SpawnItem("LaserSpidPuff")
		TNT1 A 1 Bright
		Stop
	}
}

Actor LaserSpidFlare : RedFlare { Scale 0.08 }

Actor LaserSpidPuff
{
Height 1
Radius 1
Scale 0.5
Renderstyle Add
+NOGRAVITY
+NOBLOCKMAP
+NOTELEPORT
+CLIENTSIDEONLY
+NONETID
States
	{
	Spawn:
		XXXX A 4 Bright
		XXXX BBBBCCDDDEEE 1 Bright A_FadeOut(0.05,0)
	Fade:
		XXXX E 1 Bright A_FadeOut(0.1,1)
		Loop
	}
}