Actor Damned
{
Monster
Health 1500
Height 64
Radius 24
Mass 1000
Speed 4
MeleeRange 64
Painchance "Mine", 128
Painchance 38
MeleeDamage 18
+BOSSDEATH
+NOTARGET
+FLOORCLIP
+FASTMELEE
+MISSILEMORE
+MISSILEEVENMORE
+QUICKTORETALIATE
+DONTHARMSPECIES
Species "Nobles"
Species "SatanGuard"
Damagefactor "Acid", 0.3
Damagefactor "Nobles", 0.3
Damagefactor "Fire", 0.5
//No Infighting
DamageFactor "SatanGuard", 0.0
DamageFactor "AbyssalSatyr", 0.0
Damagefactor "Heterodox", 0.0
Damagefactor "Damned", 0.0
DropItem "BossLifeEssence", 200, 25
DropItem "HEMBossArmorBonusMax35", 200
DropItem "ModdedSoulSphere", 64
DropItem "Damned sphere", 96
SeeSound "profane/sight"
ActiveSound "baron/active"
MeleeSound "imp/melee"
PainSound "baron/pain"
DeathSound "profane/death"
Obituary "%o was cursed by a Damned."
HitObituary "%o was brutalized by a Damned."
States
	{
	Spawn:
		DAMN A 10 A_Look
		Loop
	See:
		DAMN AAA 1 A_Chase("Melee","")
		DAMN AA 1 A_Chase
		DAMN BBB 1 A_Chase("Melee","")
		DAMN BB 1 A_Chase
		TNT1 A 0 A_SpawnItemEx("HoofStep2",0,0,2,0,0,-20)
		DAMN CCC 1 A_Chase("Melee","")
		DAMN CC 1 A_Chase
		DAMN DDD 1 A_Chase("Melee","")
		DAMN DD 1 A_Chase
		TNT1 A 0 A_SpawnItemEx("HoofStep2",0,0,2,0,0,-20)
		Loop
	Melee:
		DAMN EEEFFFGG 1 A_FaceTarget
		TNT1 A 0 A_GiveToTarget("HeterodoxCurse")
		TNT1 A 0 A_MeleeAttack
		DAMN FEE 3
		GoTo See	
	Missile:
		TNT1 A 0
		TNT1 A 0 A_Jump(80,"BigSpread")
	Normal:
		DAMN EEEEEFFFGG 1 Bright A_FaceTarget
		TNT1 A 0 A_CustomMissile("DamnedBall",32,0,random(0,8))
		TNT1 A 0 A_CustomMissile("DamnedBall",32,0,random(-8,0))
		DAMN FEE 3
		GoTo See
	BigSpread:
		DAMN EEEEEFFFGG 1 Bright A_FaceTarget
		TNT1 AAA 0 A_CustomMissile("DamnedBall",32,0,random(0,8))
		TNT1 AAA 0 A_CustomMissile("DamnedBall",32,0,random(-8,0))
		DAMN FEEE 3
		GoTo See
	Homer:
		DAMN EEEEEFFFGG 1 Bright A_FaceTarget
		TNT1 A 0 A_CustomMissile("DamnedHomer",32,0,0)
		DAMN FEEE 3
		GoTo See
	Pain:
		TNT1 A 0
		DAMN H 2 A_Pain
		DAMN H 3
		GoTo See
	Death:
		TNT1 A 0
		DAMN I 4 A_SpawnItemEx("GibbedGenerator",0,0,32,0,0,0,0,SXF_CLIENTSIDE,0)
		TNT1 A 0 A_Scream
		TNT1 A 0 A_PlaySound("Profane/die",6,1.0,0)
        DAMN J 8 A_Fall
		TNT1 A 0 A_BossDeath
        DAMN KLMN 8
		TNT1 A 0 A_KillMaster
        DAMN O 63000 CanRaise
        Stop
    Raise:
		TNT1 A 0
	    TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
        DAMN ONMLKJI 5
        Goto See
	}
}
	
Actor DamnedBall : BaronBall
{
Speed 22
FastSpeed 28
Scale 1.2
Decal "DoomImpScorch"
Damage (3*random(4,8))
+DONTHARMSPECIES
Damagetype "Damned"
States
	{
	Spawn:	
		BAL3 AB 1 Bright A_SpawnItemEx("DamnedBallTrail",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)	
		Loop
	Death:
		TNT1 A 0 Bright
		BAL3 CDE 3 Bright
		Stop
	XDeath:
		TNT1 A 0 Bright
		TNT1 A 0 A_SpawnItemEx("RedParticleSpawner",0,0,0,0,0,0,0,SXF_CLIENTSIDE,0)
		TNT1 AAA 0 A_CustomMissile("Kaboom10",0,0,random(0,360),CMF_AIMDIRECTION,random(0,360))
		TNT1 AAA 0 A_CustomMissile("SmokeFX4",0,0,random(0,360),CMF_AIMDIRECTION,random(0,360))
		BAL3 CDE 3 Bright
		Stop
	}
}

ACTOR DamnedBallTrail
{
Height 1
Radius 1
RenderStyle Add
+NONSHOOTABLE
+NOINTERACTION
+CLIENTSIDEONLY
+NONETID
States
	{
	Spawn:
		TNT1 A 0 Bright
		TNT1 A 0 Bright A_JumpIf(ACS_ExecuteWithResult(304) == 1, "Toaster")
		TNT1 A 1 Bright
		BAL3 ABABABABABAB 1 A_FadeOut(0.1,1)
		Stop
	Toaster:
		TNT1 A 1 Bright
		Stop
	}
}

Actor DamnedHomer : HadesTracer
{
Damage (3*random(1,8))
Damagetype ""
Damagetype "Damned"
}