ACTOR CyberImp
{
Monster
Health 150
Radius 18
Mass 200
Speed 4
Reactiontime 25
MinMissileChance 80
PainChance 70
Painchance "Mine", 128
Painchance "AdvancedImp", 0
Painchance "Shadow", 0
Height 56
Bloodcolor "Purple"
Damage (random(12,16))
+FLOORCLIP
+DONTHARMSPECIES
Species "AdvancedImp"
DamageType "AdvancedImp"
Damagefactor "Acid", 2.8
Damagefactor "Fire", 0.7
RadiusDamageFactor 0.25
//No Infighting
Damagefactor "AdvancedImp", 0.0
Damagefactor "Shadow", 0.0
Damagefactor "Nightshade", 0.0
Damagefactor "HellionFire", 0.0
Damagefactor "Catharsi15k", 0.0
Damagefactor "Catharsi10K", 0.0
DamageFactor "SoulToxic", 0.0
DamageFactor "Cacolich", 0.0
DropItem "LifeEssence", 185, 8
DropItem "HEMArmorBonusMax3", 135
SeeSound "CIMPSIT"
ActiveSound "CIMPACT"
PainSound "CIMPPAIN"
DeathSound "CIMPDTH"
HitObituary "%o was torn apart by a Fusion Imp."
Obituary "%o was fried by a Fusion Imp."
Tag "\c[n6]Fusion Imp\c-"
States
	{
	Spawn:
		CIMP A 10 A_Look
		Loop
	See:
		TNT1 A 0 A_ChangeFlag(NODROPOFF,1)
		CIMP A 1 A_Chase
		CIMP AAAA 1 A_Chase("","")
		CIMP B 1 A_Chase
		CIMP BBBB 1 A_Chase("","")
		TNT1 A 0 A_SpawnItemEx("HumanishStep2",0,0,2,0,0,-20)
		CIMP C 1 A_Chase
		CIMP CCCC 1 A_Chase("","")
		CIMP D 1 A_Chase
		CIMP DDDD 1 A_Chase("","")
		TNT1 A 0 A_SpawnItemEx("HumanishStep2",0,0,2,0,0,-20)
		Loop
	Melee:
		CIMP EF 3 A_FaceTarget
		TNT1 A 0 A_CustomMeleeAttack(random(12,16),"imp/melee","None","AdvancedImp") 
		CIMP E 3 A_FaceTarget
		Goto See
	Missile:
		TNT1 A 0
		//TNT1 A 0 A_ChangeFlag(NOTARGET,1)
		//TNT1 A 0 A_CustomMissile("BribeCaco",1,0,0,2,-90)
		TNT1 A 0 A_Jump(70,"Leap")
		CIMP EF 8 A_FaceTarget
		TNT1 A 0 A_ChangeFlag(NOTARGET,0)
		CIMP G 1 Bright A_Custommissile("ImpFushot",36,4,0)
		CIMP FFG 3 A_FaceTarget
		CIMP G 1 Bright A_Custommissile("ImpFushot",36,4,0)
		CIMP FFG 3 A_FaceTarget
		CIMP G 1 Bright A_Custommissile("ImpFushot",36,4,0)
		CIMP FFG 3 A_FaceTarget
		CIMP G 1 Bright A_Custommissile("ImpFushot",36,4,0)
		CIMP FFG 3 A_FaceTarget
		CIMP G 1 Bright A_Custommissile("ImpFushot",36,4,0)
		CIMP FFG 1 A_FaceTarget
		CIMP G 1 Bright A_Custommissile("ImpFushot",36,4,0)
		CIMP FFG 3 A_FaceTarget
		CIMP G 1 Bright A_Custommissile("ImpFushot",36,4,0)
		Goto See
	Leap:
		TNT1 A 0 A_JumpIfCloser(200,1)
		GoTo See
		TNT1 A 0 A_ChangeFlag(NODROPOFF,0)
		CIMP EEEFFF 1 A_FaceTarget
		TNT1 A 0 A_ChangeFlag(NOTARGET,1)
		CIMP GG 1 A_SkullAttack
		CIMP G 20
		CIMP G 2 A_Gravity
		TNT1 A 0 A_ChangeFlag(NODROPOFF,1)
		TNT1 A 0 A_ChangeFlag(NOTARGET,0)
		GoTo See
	Pain:
		//TNT1 A 0 A_ChangeFlag(NOTARGET,1)
		TNT1 A 0 A_ChangeFlag(NODROPOFF,1)
		//TNT1 A 0 A_CustomMissile("BribeCaco",1,0,0,2,-90)
		CIMP H 2
		CIMP H 2 A_Pain
		TNT1 A 0 A_ChangeFlag(NOTARGET,0)
		Goto See
	Death:
		TNT1 A 0
		CIMP I 8
		CIMP J 8 A_Scream
		CIMP K 6
		CIMP L 6 A_Fall
		CIMP M 63000 CanRaise
		Stop
	XDeath:
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("MutantGibbedGenerator",0,0,0,0,0,0,0,128,0)
		CIMP N 5 A_CustomMissile("CyberImpArm",32,-10,270)
		TNT1 A 0 A_GiveInventory("XDeathCheck",1)
		CIMP O 5 A_XScream
		CIMP P 5
		CIMP Q 5 A_Fall
		CIMP RST 5
		CIMP U 63000 CanRaise
		Stop
	Raise:
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
		TNT1 A 0 A_JumpIfInventory("XDeathCheck",1,"XRaise")
		CIMP MLKJI 8
		Goto See
	XRaise:
		TNT1 A 0 A_TakeInventory("XDeathCheck",1)
		CIMP TSRQPON 4
		GoTo See
	}
}

ACTOR CyberImpArm
{
Height 8
Radius 8
Speed 4
FastSpeed 4
Bouncetype Doom
+Missile
+DOOMBOUNCE
+DROPOFF
+NOBLOCKMAP
+NOTELEPORT
+CLIENTSIDEONLY
+NONETID
States
	{
	Spawn:
		CARM ABCDE 3
		Loop
	Death:
		CARM F 525
		CARM FFFFFFFFFFF 5 A_FadeOut(0.1,1)
		Stop
	}
} 

Actor ImpFushot : FusionShot
{
Damage 6
Damagetype "AdvancedImp"
+THRUSPECIES
+DONTHARMSPECIES
}