Actor HellMonarch
{
Monster
Health 750
Height 64
Radius 24
Mass 1300
Speed 6
Scale 1.15
BloodColor "Green"
MeleeRange 70
PainChance 50
Painchance "Mine", 128
MissileType "NewBaronBall"
-BOSSDEATH
+FLOORCLIP
+DONTHARMSPECIES
Species "Nobles"
//No Infighting
DamageFactor "SatanGuard", 0.0
DropItem "BossLifeEssence", 200, 16
DropItem "HEMArmorBonusMax16", 200
SeeSound "knight/sight"
ActiveSound "knight/active"
PainSound "knight/pain"
DeathSound "knight/death"
Obituary "%o was melted by a Hell Monarch."
HitObituary "%o was ripped open by a Hell Monarch."
Tag "Hell Monarch"
States
	{
	Spawn:
		BOS2 A 10 A_Look
		Loop
	See:
		BOS2 AAAABBBB 1 A_Chase
		TNT1 A 0 A_SpawnItemEx("HoofStep2",0,0,0,0,0,-20,0,128)
		BOS2 CCCCDDDD 1 A_Chase
		TNT1 AAA 0 A_FastChase
		TNT1 A 0 A_SpawnItemEx("HoofStep2",0,0,0,0,0,-20,0,128)
		Loop
	Missile:
	Melee:
		BOS2 EEE 2 Bright A_FaceTarget(45)
		BOS2 FFG 2 Bright A_FaceTarget
		BOS2 G 1 Bright A_ComboAttack
		BOS2 GFEE 2 Bright
		Goto See
	Pain:
		TNT1 A 0
		BOS2 H 2
		BOS2 H 2 A_Pain
		Goto See
	Death:
		TNT1 A 0
		BOS2 I 8 A_SpawnItemEx("GreenGibbedGenerator",0,0,0,0,0,0,0,128,0)
		BOS2 J 6 A_Scream
		BOS2 K 5 A_Fall
		BOS2 L 5
		BOS2 MN 4
		BOS2 O 63000 CanRaise
		Stop
	Raise:
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
		BOS2 O 8
		BOS2 NMLKJI 8
		Goto See
	}
}

Actor NewBaronBall : BaronBall
{
Scale 1.2
Speed 22
FastSpeed 28
Decal "DoomImpScorch"
+DONTHARMSPECIES
States
	{
	Spawn:	
		BAL6 AB 1 Bright A_SpawnItemEx("NewBaronBallTrail",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)	
		Loop
	Crash:
	Death:
		TNT1 A 0
		BAL6 CDE 3 Bright
		Stop
	XDeath:
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("GreenParticleSpawner",0,0,0,0,0,0,0,SXF_CLIENTSIDE,0)
		TNT1 AAA 0 A_CustomMissile("Kaboom7",0,0,random(0,360),CMF_AIMDIRECTION,random(0,360))
		TNT1 AAA 0 A_CustomMissile("SmokeFX4",0,0,random(0,360),CMF_AIMDIRECTION,random(0,360))
		BAL6 CDE 3 Bright
		Stop
	}
}

ACTOR NewBaronBallTrail
{
RENDERSTYLE Add
+FORCEXYBILLBOARD
+NOINTERACTION
+CLIENTSIDEONLY
+NONETID
States
	{
	Spawn:
		TNT1 A 1
	Fade:
		BAL6 AB 1 A_FadeOut(0.1,1)
		Loop
	}
}