Actor StoneKnight 30341
{
Monster
Health 1000
Height 64
Radius 24
Mass 1700
Speed 3
FastSpeed 4
Scale 1.15
BloodCOLOR "None"
BloodType "StoneBitsSpawner"
PainChance 8
Painchance "Mine", 0
Painchance "Explosion", 0
MeleeRange 78
Missiletype "LobbedRock"
+NOFEAR
-BOSSDEATH
+FLOORCLIP
+DONTRIP
+NORADIUSDMG
+NOBLOODDECALS
+QUICKTORETALIATE
+DONTHARMSPECIES
Species "Nobles"
Damagefactor "Acid", 0.0
Damagefactor "Fire", 0.1
DamageFactor "Ice", 0.1
DamageFactor "FreezerBurn", 0.1
Damagefactor "Poison", 0.0
Damagefactor "PoisonCloud", 0.0
Damagefactor "Electric", 0.01
Damagefactor "Disintegrate", 0.25
DamageFactor "PDTBFG", 0.25
DamageFactor "PDTBFGTracer", 0.25
DamageFactor "PlayerDevBall", 0.125
DamageFactor "PlayerDevBall2", 0.125
DamageFactor "PlayerDevTracer", 0.125
DamageFactor 0.75
//No Infighting
Damagefactor "Stun", 0.0
DamageFactor "SatanGuard", 0.0
DamageFactor "NobleComet", 0.0
DamageFactor "SoulToxic", 0.0
DamageFactor "Cacolich", 0.0
DropItem "BossLifeEssence", 200, 10
DropItem "BossLifeEssence", 100, 20
DropItem "HEMArmorBonusMax20", 256
SeeSound "knight/sight"
ActiveSound "knight/active"
PainSound "knight/pain"
DeathSound "knight/death"
Obituary "%o was knocked down by a Stone Knight's rocklobbing."
HitObituary "%o was slapped hard by a Stone Knight."
var int user_cant_raise;
Tag "\c[d9]Stone Knight\c-"
States
	{
	Spawn:
		STKN A 10 A_Look
		Loop
	See:
		STKN AAAAAABBBBBB 1 A_Chase("Melee","")
		TNT1 A 0 A_SpawnItemEx("HoofStep2",0,0,2,0,0,-20)
		STKN CCCCCCDDDDDD 1 A_Chase("Melee","")
		TNT1 A 0 A_SpawnItemEx("HoofStep2",0,0,2,0,0,-20)
		TNT1 A 0 A_Jump(30,"Missile")
		Loop
	Melee:
		TNT1 A 0
		TNT1 A 0 A_Jump(70,"Missile")
		STKN EF 8 A_FaceTarget
		STKN G 6 A_CustomMeleeAttack(12*random(3,7),"stoneimp/hit","None","Stun")
		Goto See
	Missile:
		TNT1 A 0
		TNT1 A 0 A_JumpIfTargetInLos("Missile2",90,JLOSF_DEADNOJUMP|JLOSF_TARGETLOS)
		GoTo See
	Missile2:
		STKN EF 5 A_FaceTarget(45)
		TNT1 A 0 A_FaceTarget
		STKN G 3 A_ThrowGrenade("LobbedRock",42)// A_MissileAttack
		GoTo See
	Pain:
		TNT1 A 0
		STKN H 2
		STKN H 2 A_Pain
		TNT1 A 0 A_Jump(128,"Missile")
		Goto See
	Death:
		TNT1 A 0
		TNT1 A 0 A_Jump(128,"RePetrification")
		STKN I 8 A_NoBlocking
		TNT1 A 0 A_PlaySound("StoneArmor/Destroy",6,1.5,0)
		TNT1 AAAAAAAAA 0 A_SpawnItemEx("StoneBitsSpawner2",0,0,35)
		TNT1 AAAAA 0 A_CustomMissile("SmokeFX3",36,0, random(0,360),2,random(0,360))
		STKN J 8 A_Scream
		STKN K 8 A_Fall
		STKN L 8
		STKN MN 8
		STKN O 63000 CanRaise
		Stop
	RePetrification:
		TNT1 A 0
		TNT1 A 0 A_SetUserVar("user_cant_raise",1)
		STKN H 1 A_Scream
		STKN H 1 A_Fall
		STKN H 20
		TNT1 AAAAAAAAAAA 0 A_SpawnItemEx("StoneBitsLarge",0,0,0,random(-8,8),random(-8,8),random(-5,11),0)
		STKN HHHHH 5 A_PlaySound("stoneimp/hit",0,1.5,0)
		TNT1 AAAAAAAAAAA 0 A_SpawnItemEx("StoneBitsLarge",0,0,0,random(-8,8),random(-8,8),random(-5,11),0)
		TNT1 A 0 A_PlaySound("StoneArmor/Destroy",6,1.5,0)
		BOS2 H 8
		TNT1 A 1 A_SpawnItemEx("HellMonarch",0,0,1,0,0,0,0,SXF_NOCHECKPOSITION)
		Stop
	Raise:
		TNT1 A 0
		TNT1 A 0 A_JumpIf(user_cant_raise == 1,"RaiseFail")
		TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
		STKN O 8
		STKN NMLKJI 8
		Goto See
	RaiseFail:
		STKN OOOOOOOOOOOOOOOOOOOO 1 A_FadeOut(0.1,1)
		Stop
	}
}