Actor AbyssalHound
{
Monster
Health 220
Height 50
Radius 30  
Mass 500
Speed 12
BloodColor "Purple"
MeleeDamage 7
MeleeRange 50
PainChance 78
Painchance "Mine", 128
Painchance "SatanGuard", 0
Painchance "AbyssalSatyr", 0
Painchance "Heterodox", 0
+FLOORCLIP
+MISSILEMORE
+DONTHARMSPECIES
Species "Fiends"
Damagefactor "Acid", 0.5
Damagefactor "Fire", 0.5
DamageFactor "SatanGuard", 0.25
DamageFactor "AbyssalSatyr", 0.25
DamageFactor "Heterodox", 0.25
DropItem "LifeEssence", 180, 5
DropItem "HEMArmorBonusMax5", 180
SeeSound "monster/Abdogsit"
AttackSound "monster/AbDogatk"
MeleeSound "monster/AbDogbit" 
PainSound "monster/AbDogpai" 
DeathSound "monster/ADogdth" 
ActiveSound "monster/AbDogact"
Obituary "%o was murdered by an Abyssal Hound."
HitObituary "An Abyssal Hound had %o for dinner."
Tag "\caAbyssal Hound\c-"
States
  {
  Spawn:
	HDOG A 10 A_Look
	Loop
  See:
	TNT1 A 0 A_JumpIfInTargetInventory("truelegendaryruneitem2",1,2)
	TNT1 A 0 A_Jump(256,2)
	TNT1 A 0 A_GiveInventory("DogDamageUp",1)
	HDOG AAAABBBBCCCCDDDDEEEEFFFF 1 A_Chase("Melee","")
	TNT1 A 0 A_Jump(142,"Missile")
	Loop
  Melee:
	HDOG GGGGG 1 A_FaceTarget(45)
	HDOG HHHHII 1 A_FaceTarget
	HDOG I 1 A_CustomMeleeAttack(7*random(1,4),"monster/AbDogbit","None","SatanGuard")
	Goto See
  Missile:
	TNT1 A 0
	TNT1 A 0 A_JumpIfTargetInLos("Missile2",90,JLOSF_DEADNOJUMP|JLOSF_TARGETLOS)
	GoTo See
  Missile2:
	TNT1 A 0
	TNT1 A 0 A_Jump(256,"Lunge","Lunge","DarkFireBalls","Normal")
	Goto Normal
  Normal:
	TNT1 A 0
	HDOG GGGGGG 1 A_FaceTarget
	HDOG HH 1 Bright A_FaceTarget
	TNT1 A 0 A_CustomMissile("AbyssalHoundBall",28,0,0)
	HDOG I 8
	GoTo See 
  Lunge:
	TNT1 A 0
	TNT1 A 0 A_JumpIfCloser(200,1)
	Goto See
	TNT1 A 0 A_PlaySound("monster/Abdogatk")
	HDOG AAAAAAAABBBB 1 A_FaceTarget
	TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,1)
	TNT1 A 0 ThrustThingZ(0,18,0,1)
	HDOG CC 1 A_Recoil(-24)
	TNT1 A 0 A_JumpIfInTargetInventory("truelegendaryruneitem2",1,2)
	TNT1 A 0 A_Jump(256,3)
	TNT1 AA 0 A_CustomMissile("PinkyLunge",18,0,0,CMF_AIMDIRECTION)
	HDOG C 3 A_CustomMissile("PinkyLunge",18,0,0,CMF_AIMDIRECTION)
	HDOG DDDDDD 1
	HDOG EEEE 1 A_ScaleVelocity(0.2)
	TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,0)
	HDOG FFFF 1 A_ScaleVelocity(0)
	Goto See
  DarkFireBalls:
	TNT1 A 0
	HDOG GGGGGGGGG 1 A_FaceTarget(45)
	TNT1 A 0 A_FaceTarget
	HDOG HH 1 Bright A_CustomMissile("HeterodoxBall",28,0,random(-11,11))
	HDOG I 12
	GoTo See
  Pain:
	TNT1 A 0
	HDOG J 2
	HDOG J 2 A_Pain
	Goto See
  Death:
	TNT1 A 0
	HDOG K 3
	HDOG L 3 A_Scream
	HDOG M 4
	HDOG N 4 A_Fall
	HDOG OP 3
	HDOG Q 63000 CanRaise
	Stop
  Raise:
	TNT1 A 0
	TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
	HDOG QPONMLK 5
	Goto See
  }
}

Actor AbyssalHoundBall : PhaseImpBall
{
Species ""
Species "Fiends"
DamageType ""
DamageType "SatanGuard"
+THRUSPECIES
+DontHurtSpecies
+DontHarmSpecies
}