Actor BloodSkull
{
Monster
Health 75
Height 34
Radius 10
Mass 150
Scale 0.65
Speed 6
FloatSpeed 6
FastSpeed 6
ReactionTime 23
Painchance "SatanGuard", 0
Painchance "BloodElemental", 0
Painchance "Broat", 0
Painchance 57
Damage (random(7,10))
+FLOAT
+NOGRAVITY
+DONTFALL
+LookAllAround
+NoTarget
+NoTargetSwitch
+NOICEDEATH
+DontHurtSpecies
+DontHarmSpecies
+DontHarmClass
Species "EleSouls"
Species "Souls"
Damagetype "BloodSkull"
Damagefactor "Poison", 0.0
Damagefactor "PoisonCloud", 0.0
DamageFactor "PDTBFG", 0.25
DamageFactor "PDTBFGTracer", 0.25
DamageFactor "PlayerDevBall", 0.125
DamageFactor "PlayerDevBall2", 0.125
DamageFactor "PlayerDevTracer", 0.125
DamageFactor "PlayerDevTracer", 0.125
DamageFactor "LegendaryPlayer", 0.3
DamageFactor "LegendaryGuruPlayer", 0.3
DamageFactor 0.75
//No Infighting
Damagefactor "Wicked", 0.0
Damagefactor "BloodSkull", 0.0
Damagefactor "BloodElemental", 0.0
Damagefactor "Broat", 0.0
DamageFactor "SoulToxic", 0.0
DamageFactor "BombBreath", 0.0
Damagefactor "EleSouls", 0.0
DropItem "LifeEssence", 180
DropItem "HEMArmorBonusMax1", 180
SeeSound "BSkull/See"
PainSound "BSkull/Pain"
DeathSound "BSkull/Death"
ActiveSound "Skull/Active"
Obituary "%o was defiled by a Blood Skull."
HitObituary "%o's head was smashed by a Blood Skull."
Tag "\c[k7]Blood Skull\c-"
States
	{
	Spawn:
		SWBS A 10 A_Look
		Loop
	See:
		SWBS A 1 A_Chase
		Loop
	Missile:
		TNT1 A 0
		SWBS A 1 A_Jump(96,"BloodSpit")
	Normal:
		SWBS AAAAAAAAAA 1 A_FaceTarget
		SWBS B 1 A_SkullAttack(18)
	RamLoop:
		SWBS B 55
		TNT1 A 0 A_Stop
		TNT1 A 0 A_MonsterRefire(0,"See")
		TNT1 A 0 A_Jump(96,"See")
		TNT1 A 0 A_JumpIfCloser(200,"BloodSpit")
		GoTo See
	BloodSpit:
		SWBS AAB 1 A_FaceTarget
		SWBS B 1 Bright A_CustomMissile("BloodSpit",12,0,0,0,0)
		SWBS BA 2
		Goto See
	Pain:
		TNT1 A 0
		SWBS A 2 A_Pain
		Goto See
	Vanish:
		TNT1 A 0
		SWBS A 2 A_FadeOut(0.1,1)
		Wait
	Death:
		TNT1 A 0
		SWBS C 6 A_Fall
		TNT1 A 0 A_SpawnItemEx("OrangeParticleSpawner",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION|SXF_CLIENTSIDE)
		TNT1 AAA 0 A_CustomMissile("Kaboom10",0,0,random(0,360),2,random(0,360))	
		TNT1 AAA 0 A_CustomMissile("SmokeFX2",0,0,random(0,360),2,random(0,360))
		TNT1 AAAA 0 A_SpawnItemEx("Debris",0,0,15,Random(4,-4),Random(4,-4),Random(4,8),0,SXF_NOCHECKPOSITION|SXF_CLIENTSIDE)
		SWBS D 5 Bright A_Scream
		TNT1 A 0 A_SetTranslucent(0.8,0)
		SWBS EFGH 5 Bright
		TNT1 A 1 Bright
		Stop
	}
}

Actor BloodSkull~ : BloodSkull
{
States
	{
	BloodSpit:
		SWBS AAB 1 A_FaceTarget
		SWBS B 1 Bright A_CustomMissile("BloodSpit",12,0,0,0,0)
		SWBS BA 2
		TNT1 A 0 A_JumpIfInventory("Tic",10,"Vanish")
		TNT1 A 0 A_GiveInventory("Tic",1)
		Goto See
	}
}

Actor BloodSkullSpawner : ShadowSlaveSpawner
{
+THRUACTORS
States
	{
	Spawn:
		TNT1 A 5
	Death:
		TNT1 A 1
		TNT1 A 1 A_SpawnItemEx("TeleportFog",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION)
		TNT1 A 1 A_SpawnItemEx("BloodSkull~",0,0,0,0,0,0,0,SXF_ABSOLUTEPOSITION|SXF_SETMASTER|SXF_TRANSFERPOINTERS)
		Stop
	}
}