ACTOR MRLZombie
{ 
Monster 
Health 300
Height 56
Radius 20 
Mass 100 
Speed 2
Painchance "Mine", 128
PainChance "ZombieRocket", 0
PainChance 60
+FLOORCLIP
+NODROPOFF
+QUICKTORETALIATE
+DONTHARMSPECIES
Species "EliteZombies"
Damagefactor "Acid", 2.1
Damagefactor "Fire", 0.5
Damagefactor "Mine", 0.35
DamageFactor "ZombieRocket", 0.25
//No Infighting
Damagefactor "ZGrenade", 0.0
DamageFactor "ZombieCannon", 0.0
Damagefactor "HTZombie", 0.0
DamageFactor "MiniRocket", 0.0
Damagefactor "ZExplosiveBullets", 0.0
DamageFactor "SoulToxic", 0.0
DamageFactor "Cacolich", 0.0
DropItem "ArmorPlate" 120
DropItem "HealthFlask", 120, 2
DropItem "AmmoPack", 100, 2
DropItem "ArmorCharge", 60, 2
DropItem "HandGrenadeAmmo", 60, 1
DropItem "MineAmmo", 50, 1
DropItem "Missile", 180, 5
SeeSound "PNZombie/See"
PainSound "PNZombie/Pain"
DeathSound "PNZombie/Die"
ActiveSound "PNZombie/Act"
Obituary "%o got noobed by a Mini Rocket Launcher Zombieman." 
Tag "\cbMini Rocket Launcher Zombieman\c-"
States
	{
	Spawn: 
		MPOS AB 10 A_Look
		Loop
	See:
		MPOS A 1 A_Chase
		MPOS AAAAA 1 A_Chase("","")
		MPOS B 1 A_Chase
		MPOS BBBBB 1 A_Chase("","")
		TNT1 A 0 A_SpawnItemEx("Footstep2",0,0,2,0,0,-20)
		MPOS C 1 A_Chase
		MPOS CCCCC 1 A_Chase("","")
		MPOS D 1 A_Chase
		MPOS DDDDD 1 A_Chase("","")
		TNT1 A 0 A_SpawnItemEx("Footstep2",0,0,2,0,0,-20)
		Loop
	Missile:
		//TNT1 A 0 A_ChangeFlag(NOTARGET,1)
		//TNT1 A 0 A_CustomMissile("BribeCaco",1,0,0,2,-90)
		MPOS EEEE 5 A_FaceTarget(45)
		//TNT1 A 0 A_ChangeFlag(NOTARGET,0)
		TNT1 A 0 A_PlaySound("MiniRocketFire",CHAN_AUTO,1.0,0)
		MPOS F 5 Bright A_CustomMissile("MiniRocket",40,10,random(-2,2),CMF_TRACKOWNER)
		MPOS E 5 A_FaceTarget
		TNT1 A 0 A_PlaySound("MiniRocketFire",CHAN_AUTO,1.0,0)
		MPOS F 5 Bright A_CustomMissile("MiniRocket",40,10,random(-2,2),CMF_TRACKOWNER)
		MPOS E 5 A_FaceTarget
		TNT1 A 0 A_PlaySound("MiniRocketFire",CHAN_AUTO,1.0,0)
		MPOS F 5 Bright A_CustomMissile("MiniRocket",40,10,random(-2,2),CMF_TRACKOWNER)
		MPOS E 5 A_FaceTarget
		TNT1 A 0 A_PlaySound("MiniRocketFire",CHAN_AUTO,1.0,0)
		MPOS F 5 Bright A_CustomMissile("MiniRocket",40,10,random(-2,2),CMF_TRACKOWNER)
		MPOS G 5
		Goto See
	Pain:
		//TNT1 A 0 A_ChangeFlag(NOTARGET,1)
		//TNT1 A 0 A_CustomMissile("BribeCaco",1,0,0,2,-90)
		MPOS H 2
		//TNT1 A 0 A_ChangeFlag(NoTarget,0)
		MPOS H 2 A_Pain 
		Goto See 
	Death:
		MPOS I 5 
		MPOS J 5 A_Scream 
		MPOS K 5 
		MPOS L 5 A_Fall 
		TNT1 A 0 A_SpawnItem("BodyCrash",0,0,0,0)
		MPOS M 63000 CanRaise
		Stop 
	XDeath:
		MPOS N 3 A_SpawnItemEx("GibbedGenerator",0,0,0,0,0,0,0,128,0) 
		TNT1 A 0 a_giveinventory("xdeathcheck",1)
		MPOS O 5 A_XScream 
		MPOS P 5 
		MPOS Q 5 A_Fall 
		MPOS RSTU 5
		MPOS V 63000 CanRaise
		Stop 
	Raise:
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
		TNT1 A 0 a_jumpifinventory("xdeathcheck",1,"Xraise")
		MPOS MJKJI 5 
		Goto See 
	Xraise:
		TNT1 A 0 A_TakeInventory("XDeathCheck",1)
		MPOS VUTSRQPON 3
		Goto See
	}
}

Actor MiniRocket
{
Projectile
Height 5
Radius 6
Speed 32
Damage 2
+STRIFEDAMAGE
+THRUSPECIES
+MTHRUSPECIES
+DONTHARMSPECIES
Damagetype "MiniRocket"
SeeSound ""
DeathSound "MiniRocketExpl"
States
	{
	Spawn:
		MICR A 1 Bright A_SpawnItemEx("MissileTrail",0,0,0,0,0,0,0,SXF_CLIENTSIDE|SXF_NOCHECKPOSITION,0)
		TNT1 A 0 Bright A_PlaySound("MiniRocketFly",6,1.0,1)
		Loop
	Death:
		TNT1 AAA 0 Bright A_StopSound(6)
		TNT1 A 0 Bright A_SpawnItemEx("OrangeParticleSpawner",0,0,1,0,0,0,0,SXF_CLIENTSIDE,0)
		TNT1 AAAA 0 Bright A_CustomMissile("Kaboom9",0,0,random(0,360),CMF_AIMDIRECTION,random(0,360))
		TNT1 AAAA 0 Bright A_CustomMissile("SmokeFX4",0,0,random(0,360),CMF_AIMDIRECTION,random(0,360))
		TNT1 A 0 Bright A_Explode(10,30,1,1)
		TNT1 A 0 Bright A_SetTranslucent(0.85,1)
		H2BL JKLMN 4 Bright
		Stop
	}
}

Actor PMiniRocket : MiniRocket
{
Damage 24
-STRIFEDAMAGE
Species "Player"
Damagetype "Explosion"
}