Actor PyroZombie
{
Monster
Health 125
Height 56
Radius 18
Speed 4
MaxTargetRange 1024
Reactiontime 25
Painchance 55
Painchance "Mine", 128
+FLOORCLIP
+NODROPOFF
+DONTHARMSPECIES
Species "EliteZombies"
Damagefactor "Fire", 0.0
//No Infighting
Damagefactor "HTZombie", 0.0
Damagefactor "ZGrenade", 0.0
Damagefactor "ZExplosiveBullets", 0.0
DamageFactor "SoulToxic", 0.0
DamageFactor "Cacolich", 0.0
DropItem "ArmorCharge", 150, 2
DropItem "HandGrenadeAmmo", 150, 1
DropItem "AmmoPack", 190, 2
DropItem "HealthFlask", 120, 2
DropItem "MineAmmo", 120, 1
AttackSound "weapons/flamer"
ActiveSound "grunt/active"
PainSound "grunt/pain"
DeathSound "grunt/death"
Obituary "%o was blazed by a Pyroblast Zombieman."
Tag "\ciPyroblast Zombieman\c-"
States
	{
	Spawn:
		FLMZ A 10 A_Look
		Loop
	See:
		FLMZ A 1 A_Chase
		FLMZ AAAAA 1 A_Chase("","")
		FLMZ B 1 A_Chase
		FLMZ BBBBB 1 A_Chase("","")
		FLMZ A 0 A_SpawnItemEx("Footstep2",0,0,2,0,0,-20)
		FLMZ C 1 A_Chase
		FLMZ CCCCC 1 A_Chase("","")
		FLMZ D 1 A_Chase
		FLMZ DDDDD 1 A_Chase("","")
		TNT1 A 0 A_SpawnItemEx("FootStep2",0,0,2,0,0,-20)
		Loop
	Missile:
		//TNT1 A 0 A_ChangeFlag(NOTARGET,1)
		//TNT1 A 0 A_CustomMissile("BribeCaco",1,0,0,2,-90)
		FLMZ EEEE 3 A_FaceTarget(45)
		//TNT1 A 0 A_ChangeFlag(NOTARGET,0)
		FLMZ FF 1 Bright A_FaceTarget
		TNT1 A 0 A_PlaySound("Weapons/PyroSGShot")
		TNT1 AAAA 0 A_CustomMissile("ZombieFlamethrowerShot",36,0,random(-6,6),CMF_TRACKOWNER)
		FLMZ EEEE 3 A_FaceTarget
		FLMZ FF 1 Bright A_FaceTarget
		TNT1 A 0 A_PlaySound("Weapons/PyroSGShot")
		TNT1 AAAA 0 A_CustomMissile("ZombieFlamethrowerShot",36,0,random(-6,6),CMF_TRACKOWNER)
		TNT1 A 0 A_Jump(72,"Missile")
		FLMZ E 5 
		GoTo See
	Pain:
		//TNT1 A 0 A_ChangeFlag(NOTARGET,1)
		//TNT1 A 0 A_CustomMissile("BribeCaco",1,0,0,2,-90)
		FLMZ G 2 A_Pain
		//TNT1 A 0 A_ChangeFlag(NOTARGET,0)
		FLMZ G 4
		GoTo See
	Death:
		TNT1 A 0
		FLMZ G 3 A_Scream
		FLMZ H 4 A_Fall
		TNT1 A 0 A_JumpIf(ACS_ExecuteWithResult(298) == 1, "AlwaysDrop")
		TNT1 A 0 A_SpawnItemEx("Welder",0,0,8,random(0,8),random(0,8),2,random(0,360),0,224)
		TNT1 A 0 A_SpawnItemEx("Gas",0,0,8,random(0,8),random(0,8),2,random(0,360),0,64)
		Goto EndDrop
	AlwaysDrop:
		TNT1 A 0 A_SpawnItemEx("Welder",0,0,8,random(0,8),random(0,8),2,random(0,360),0,0)
		TNT1 A 0 A_SpawnItemEx("Gas",0,0,8,random(0,8),random(0,8),2,random(0,360),0,224)
		Goto EndDrop
	EndDrop:
		FLMZ IJK 4
		TNT1 A 0 A_SpawnItem("BodyCrash")
		FLMZ L 63000 CanRaise
		Stop
	XDeath:
		TNT1 A 0
		FLMZ G 3 A_XScream
		TNT1 A 0 A_Fall
		TNT1 A 0 A_JumpIf(ACS_ExecuteWithResult(298) == 1, "XAlwaysDrop")
		TNT1 A 0 A_SpawnItemEx("Welder",0,0,8,random(0,8),random(0,8),2,random(0,360),0,224)
		TNT1 A 0 A_SpawnItemEx("Gas",0,0,8,random(0,8),random(0,8),2,random(0,360),0,64)
		Goto XEndDrop
	XAlwaysDrop:
		TNT1 A 0 A_SpawnItemEx("Welder",0,0,8,random(0,8),random(0,8),2,random(0,360),0,0)
		TNT1 A 0 A_SpawnItemEx("Gas",0,0,8,random(0,8),random(0,8),2,random(0,360),0,224)
		Goto XEndDrop
	XEndDrop:
		FLMZ O 3
		TNT1 A 0 A_GiveInventory("XDeathCheck",1)
		TNT1 A 0 A_SpawnItemEx("GibbedGenerator",0,0,0,0,0,0,0,128,0) 
		FLMZ PQRSTUV 5
		FLMZ W 63000 CanRaise
		Stop
	Raise:
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
		TNT1 A 0 A_JumpIfInventory("XDeathCheck",1,"XRaise")
		FLMZ LKJIH 4
		GoTo See
	XRaise:
		TNT1 A 0 A_TakeInventory("XDeathCheck",1)
		FLMZ LKJIH 4
		GoTo See
	}
}

Actor ZombieFlamethrowerShot : BaseFireSpawner
{
Damage (random(5,15))
Species "EliteZombies"
States
	{
	Death:
		TNT1 AAA 0 A_StopSound(CHAN_BODY)
		TNT1 A 0 A_Stop
		TNT1 A 0 A_NoGravity
		TNT1 A 0 A_SpawnItemEx("OrangeParticleSpawner",0,0,0,0,0,0,0,SXF_CLIENTSIDE,0)
		TNT1 AA 0 A_CustomMissile("Kaboom69",0,0,random(0,360),CMF_AIMDIRECTION,random(0,360))
		TNT1 AA 0 A_CustomMissile("SmokeFX7",0,0,random(0,360),CMF_AIMDIRECTION,random(0,360))
		TNT1 A 0 A_SpawnItemEx("PyroZombieFlare",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION|SXF_TRANSFERPOINTERS|SXF_SETMASTER)
		//TNT1 AAAA 0 A_SpawnItemEx("PyroZombieFlare",0,0,0,random(2,4),random(2,4),2,random(0,360),SXF_NOCHECKPOSITION|SXF_TRANSFERPOINTERS|SXF_SETMASTER)
		FRTM CDE 3 Bright
		Stop
	}
}

Actor PyroZombieFlare : BaseFireFlare
{
Species "EliteZombies"
Obituary "%o was blazed by a Pyroblast Zombieman."
States
	{
	Spawn:
		TNT1 A 0 Bright
		TNT1 A 0 Bright A_SetUserVar("user_firedamage",15)
		TNT1 A 0 Bright A_Die
		Goto Death
	}
}