Actor PyroCannon : Weapon 24004
{
  Inventory.PickupMessage "You got the pyro cannon prototype!"
  Obituary "%o was incinerated by %k's pyro cannon."
  Weapon.PreferredSkin "DemonTechBFG10K-Marine"
  Weapon.SelectionOrder 3
  Weapon.AmmoType "Gas"
  Weapon.AmmoGive 50
  Weapon.AmmoUse 150
  +INVENTORY.UNDROPPABLE
  States
  {
  Spawn:
    WPYR A -1
    Loop
  Ready:
	PYRG A 1 A_WeaponReady
    Loop
  Deselect:
    PYRG A 1 A_Lower
    loop
  Select:
    TNT1 A 0 A_PlayWeaponSound("weapons/PCNNpickup")
    PYRG A 1 A_Raise
    goto select+1
  Fire:
    PYRG A 5
    PYRG B 8 Bright A_GunFlash
	TNT1 A 0 A_PlaySound("weapons/PCNNF")
    PYRG C 10 Bright A_FireCustomMissile("PlayerPyroShot", 0, 1, 0, 0)
    PYRG DEFG 5 Bright
	TNT1 A 0 A_PlaySound("weapons/dtech10ksteam")
	PYRG AAAAAAAAAAAA 1 A_FireCustomMissile("DTech10KSteam",-58+Random(-4,4),0,0,0)
	PYRG A 20
    Goto Ready
  Flash:
    TNT1 A 8 A_Light1
    TNT1 A 10 A_Light2
    TNT1 A 15 A_Light1
    TNT1 A 1 A_Light0
    Stop
  }
}
Actor Gas : Ammo 14002
{
  Inventory.PickupSound "misc/pickup"
  Inventory.Amount 50
  Inventory.MaxAmount 300
  Ammo.BackpackAmount 25
  Ammo.BackpackMaxAmount 600
  Inventory.PickupMessage "You picked up a gasoline cannister"
  Inventory.Icon "AGASA0"
  States
  {
  Spawn:
    AGAS A -1
    stop
  }
}

Actor BigGas : Gas 14003
{
  Inventory.Amount 120
  Inventory.PickupMessage "You picked up a gasoline pack"
  Inventory.Icon "AGASB0"
  States
  {
  Spawn:
    AGAS B -1
    stop
  }
}
ACTOR PlayerPyroShot
{
   PROJECTILE
   +SeekerMissile
   +FORCERADIUSDMG
   +NoGravity
   +MTHRUSPECIES
   +NODAMAGETHRUST
   +DONTREFLECT
   +Friendly
   +DontHurtSpecies
   SeeSound "weapons/firbfi"
   DeathSound "weapons/hellex"
   Species "Player"
   DamageType "PlayerPyro"
   Obituary "%o was incinerated by a pyro cannon."
   Alpha 1.0
   Scale 1.4
   RenderStyle Add
   Speed 45
   FastSpeed 50
   PROJECTILE
   Damage 300
   Radius 11
   Height 6
   states
   {
   Spawn:
	TNT1 A 0 A_Explode(600,64,0,1)
    HFBA ABC 1 A_SpawnItemEx("PHFExTrail",0,0,0,0,0,0,0)
    TNT1 A 0 BRIGHT A_SeekerMissile(10,10)
    Goto Spawn+2
   Death:
	  TNT1 A 0 Radius_Quake(15,20,0,20,0)
	  HFBA D 0 Bright A_CustomMissile("PFuelExplosion01",0,0,0,6)
      HFBA D 0 Bright A_CustomMissile("PFuelExplosion01",0,0,45,6)
      HFBA D 0 Bright A_CustomMissile("PFuelExplosion01",0,0,90,6)
      HFBA D 0 Bright A_CustomMissile("PFuelExplosion01",0,0,135,6)
      HFBA D 0 Bright A_CustomMissile("PFuelExplosion01",0,0,180,6)
      HFBA D 0 Bright A_CustomMissile("PFuelExplosion01",0,0,225,6)
      HFBA D 0 Bright A_CustomMissile("PFuelExplosion01",0,0,270,6)
      HFBA D 0 Bright A_CustomMissile("PFuelExplosion01",0,0,315,6)
      HFBA D 0 Bright A_Mushroom("PlayerMushroomFireballs",8)
	  TNT1 A 0 A_Explode(5000,486)
      HFBA DEFGHIJKLMN 1 BRIGHT 
	  TNT1 A 0 A_SpawnItemEx("PyroShotEx",0,0,0,0,0,0,0)
      Stop
   }
}
Actor PHFExTrail
{
	+CLIENTSIDEONLY 
	+NOBLOCKMAP
	+NOGRAVITY 
	+NOINTERACTION
	States 
	{
	Spawn:
		TNT1 A 0
		TNT1 A 1 A_SpawnItemEx("HFKaboom",-8,0,0,-6, 0,random(-1,1),0)
		Stop
	}
}
ACTOR PFuelExplosion01
{
   Radius 8
   Height 8
   Speed 6
   Damage 10
   PROJECTILE
   RENDERSTYLE ADD
   Species "Player"
   DamageType "PlayerPyro"
   
   +RIPPER
   +BLOODLESSIMPACT
   +DontHurtSpecies
   +SPECTRAL
   +Friendly
   +DontHarmSpecies
   SeeSound "weapons/firex3"
   ALPHA 0.80
   States
   {
   Spawn:
      TNT1 AAAAA 4 A_SpawnItem("PFuelExplosion02",0,0)
      Stop
   }
}

ACTOR PFuelExplosion02
{   
   Radius 5
   Height 5
   Speed 0
   Damage 10
   PROJECTILE
   RENDERSTYLE ADD
   +SPECTRAL
   +Friendly
   +DontHurtSpecies
   +DontHarmSpecies
   species "Player"
   DamageType "PlayerPyro"
   ALPHA 0.80
   SeeSound "weapons/firex3"
   States
   {
   Spawn:
      RPEX A 2 Bright
      RPEX B 2 Bright A_Explode (10,96,0)
      RPEX CDEFGHIJKLMNOPQRSTU 2 Bright
      stop
   }
}
ACTOR PlayerMushroomFireballs
{
   Radius 10
   Height 8
   Damage 30
   PROJECTILE  
   RENDERSTYLE Translucent 
   Alpha 1
   Scale 1.0
   Speed 35
   SeeSound "imp/attack"
   DeathSound "comet/explosion"
   Species "Player"
   DamageType "PlayerPyro"
   BounceCount 3
   -NoGravity
   +DoomBounce
   +SKYEXPLODE
   +DontHurtSpecies
   +SPECTRAL
   +Friendly
   +DontHarmSpecies
   states
   {
	Spawn:
	TNT1 A 1
	TNT1 A 0 A_PlaySoundEx("HFCyb/rocket", 1, 0, 2)
	Goto Fly
	Fly:
		FRTB AB 1 BRIGHT A_SpawnItem("HFCybFireballTrail")
		Loop
     Death:
		TNT1 A 0 A_Explode(160, 192)//Damage, Radius
		TNT1 A 0 A_SpawnItemEx("LCABaseScorch", 0, 0, 0, 0, 0, 0, Random(0,359))
        TNT1 AAAAAA 0 A_CustomMissile ("OrangeParticleSpawner", 0, 0, random (0, 360), 2, random (0, 180))
		TNT1 A 0 A_SpawnItemEx("PlayerSuperMeteor_m_Explosion",0,0,0,0,0,0,0,128,0)
	    EXPL A 0 Radius_Quake(15,20,0,20,0)
		TNT1 AAAA 0 A_SpawnItemEx("SuperMeteor_m_FX_Smoke", 0, 0, 0, 0.01 * Random(-125, 125), 0.01 * Random(-125, 125), 0.01 * Random(25, 245), 0, 128, 0)
		BOOM ABCDEFGHIJKLMNOP 2 BRIGHT
		Stop
   }
}

Actor PlayerSuperMeteor_m_Explosion : SuperMeteor_m_Explosion
{
Species "Player"
DamageType "PlayerPyro"
}