ACTOR ColdNightmare : BullFiend 
{ 
    Renderstyle Translucent
    Alpha 0.05
    Health 300
    PainChance 80
	Speed 14
	Scale 1.1
	MaxTargetRange 750
    SeeSound "magma/sight"
    PainSound "monster/psopain"
    DeathSound "magma/death"
    ActiveSound "magma/active"
	AttackSound "magma/attack"
	DropItem "LifeEssence" 120
	DropItem "ArmorBonusMax" 120
	DropItem "NewCellPack" 250
	DropItem "Freezer Rifle" 40 1 
	BloodColor "LightBlue"
	DamageFactor "Ice", 0.0
    DamageFactor "FreezerBurn", 0.0
	+MissileMore
	+NOICEDEATH
    Obituary "%o could not see the Cold Nightmare and was frostbitten."
	HitObituary "%o was gnawed on by a Cold Nightmare." 
	States 
	{ 
	Spawn: 
	    CNSP E 0 A_SetTranslucent(0.05)
		CNSP A 12 A_Look
		CNSI A 12 A_Look
        Loop
	See: 
	    CNSP E 0 A_SetTranslucent(0.05)
        CNSP AABB 2 A_Chase
        TNT1 A 0 A_SpawnItem("HeavyFleshStep",0,0,0,0)
        CNSP CCDD 2 A_Chase
        TNT1 A 0 A_SpawnItem("HeavyFleshStep",0,0,0,0)
        Loop 
	Melee: 
	    CNSP E 0 A_SetTranslucent(0.05)
        CNSP EF 5 A_FaceTarget
        CNSP G 4 A_MeleeAttack
        CNSP E 5 A_FaceTarget
        Goto See
	Missile:
	    CNSP E 0 A_SetTranslucent(0.05)
		TNT1 A 0 A_Jump(128,"Lunge")
	Normal:
		CNSP E 0 A_SetTranslucent(0.10)
        CNSP G 1 A_SetTranslucent(0.25)
        CNSP G 1 A_SetTranslucent(0.45)
	    CNSP GE 5 A_FaceTarget		
	    CNSP F 6 Bright A_CustomMissile("CNIceBall", 32, 0, 0)
		CNSP E 3
        CNSP E 1 A_SetTranslucent(0.45)
        CNSP E 1 A_SetTranslucent(0.25)
		CNSP E 0 A_SetTranslucent(0.05)
		Goto See
	Lunge:
	    TNT1 A 0 A_JumpIfCloser(250,1)
	    Goto See
		CNSP E 0 A_SetTranslucent(0.05)
		TNT1 A 0 A_PlaySound("magma/attack")
	    CNSP EF 7 A_FaceTarget
		TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,1)
	    TNT1 A 0 ThrustThingZ(0,20,0,1)
	    CNSP F 2 A_Recoil(-28)
	    CNSP F 3 A_CustomMissile("PinkyLunge",18,0,0,CMF_AIMDIRECTION)
	    CNSP G 6
	    CNSP G 2 A_ScaleVelocity(0.2)
		TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,0)
	    CNSP G 1 A_ScaleVelocity(0)
	    Goto See
	Pain: 
	    CNSP E 0 A_SetTranslucent(0.05)
		TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,0)
        CNSP H 4 A_Pain
        Goto See
	Death: 
	    CNSP E 0 A_SetTranslucent(0.05)
	    TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,0)
        CNSP I 5 
        CNSP J 5 A_Scream
        CNSP K 4
        CNSP L 4 A_NoBlocking     
        CNSP M 4 A_SpawnItem("BodyCrash",0,0,0,0)
        CNSP N -1 
        Stop
	XDeath:
		CNSP E 0 A_SetTranslucent(0.05)
	    TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,0)
	    CNSP I 3
        CNSX A 3 A_XScream
        CNSX B 3 A_SpawnItemEx("BlueGibbedGenerator",0,0,0,0,0,0,0,128,0)
        CNSX C 3 A_NoBlocking
        CNSX D 3 A_SpawnItem("BodyCrash",0,0,0,0)
	    CNSX EFG 3
        CNSX H -1 
        Stop
	Raise: 
	    TNT1 A 0
	    TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
        CNSP NMLKJI 5 
        Goto See 
        }
}

Actor CNIceBall : FRZRBehBomb{
Speed 16
FastSpeed 20
Damage 8
DamageType "DTFiendEx"
States
{
  Death:
	TNT1 AAA 0 A_CustomMissile("Bluekaboom4",0,0,random(0,360),2,random(0,360))
	TNT1 AAA 0 A_CustomMissile("SmokeFX4",0,0,random(0,360),2,random(0,360))	
	SHEX DCEFG 3 Bright
	Stop
    }
}