ACTOR CryoDemon : HellKnight 31155
{ 
Health 750
PainChance 80
Scale 1.05
Bloodcolor "blue"
MeleeDamage 8
DamageFactor "PlayerFireSword", 2.0
DropItem "LifeEssence" 120
DropItem "ArmorBonusMax" 120
DamageFactor "NobleComet", 0.0
DropItem "Freezer Rifle" 100 1
DamageFactor "Ice", 0.0
DamageFactor "FreezerBurn", 0.0
Species "Nobles"
+MISSILEMORE
+FASTMELEE
+QUICKTORETALIATE
+NoIceDeath
Obituary "A Cryo Demon turned %o into a popsicle." 
HitObituary "A Cryo Demon tore %o apart."
SeeSound "monster/ar2sit" 
ActiveSound "pyro/active"
PainSound "superbaron/pain"
DeathSound "monster/ar2dth"
MeleeSound "baron/melee"
States 
{ 
Spawn: 
        CRYO A 7 Bright A_Look
		CRYO A 7 Bright A_Look
        Loop 
See: 
        CRYO AABB 3 Bright A_Chase
        TNT1 A 0 Bright A_SpawnItem("HoofStep",0,0,0,0)
        CRYO CCDD 3 Bright A_Chase
        TNT1 A 0 Bright A_SpawnItem("HoofStep",0,0,0,0)
        Loop
Missile:  
        TNT1 A 0 Bright A_Jump(128,"Comet","FloorHugger")
Normal:
        CRYO EF 7 Bright A_FaceTarget 
		CRYO G 1 Bright A_CustomMissile("CBall", 32, 0, 0)		
		TNT1 A 0 Bright A_CustomMissile("CBall", 32, 0, -5)
		CRYO G 5 Bright A_CustomMissile("CBall", 32, 0, 5)
        CRYO IJ 7 Bright A_FaceTarget 
		CRYO K 1 Bright A_CustomMissile("CBall", 32, 0, 0)		
		TNT1 A 0 Bright A_CustomMissile("CBall", 32, 0, -5)
		CRYO K 5 Bright A_CustomMissile("CBall", 32, 0, 5)		
		TNT1 A 0 Bright A_Jump(87,"Comet","FloorHugger")
        Goto See		
Comet:
        CRYO MN 8 Bright A_FaceTarget 	
        CRYO O 7 Bright A_Custommissile("CryoComet",32,0,0,0)	
		TNT1 A 0 Bright A_Jump(87,"FloorHugger")
        Goto See
FloorHugger:
        CRYO MN 8 Bright A_FaceTarget 	
        CRYO O 8 Bright A_Custommissile("CIceSpikeSpawner",16,0,0,0)	
		Goto See
Melee:
        CRYO EF 8 Bright A_FaceTarget 
        CRYO G 7 Bright A_MeleeAttack 		
        Goto See
Pain: 
		TNT1 A 0 A_Jump(61,"PainMissile")
        CRYO Q 4 Bright A_Pain
        Goto See 
PainMissile:
		CRYO Q 4 Bright A_Pain
        Goto Missile 
Death: 
        CRYO R 8 Bright
        CRYO S 7 Bright A_Scream 
		TNT1 AAA 0 Bright A_SpawnItemEx("BlueParticleSpawner", Random(10,-10), Random(10,-10), Random(30,60), 0, 0, 0, 0, 128) 
        CRYO U 5 Bright A_Fall 
        CRYO VW 5 Bright
        TNT1 AAAA 0 A_CustomMissile("SmokeFX", Random(30,60), 0, random(0,360), 2, random(0,360))			
    	CRYO X 4 Bright A_CustomMissile("CryoSoul",86,0,0,2,90)
    	CRYO Z 4 Bright
        TNT1 A -1
	    Stop
Raise: 
	    TNT1 A 0
	    TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
        CRYO ZYXWVUTSR 5 Bright
        Goto See 
        } 
}
ACTOR CryoSoul : FamineSoul
{   
States
{
Spawn:
    TNT1 A 0
    TNT1 A 0 A_JumpIf(ACS_ExecuteWithResult(304) == 1, "Toaster")
    CRSP ABCD 4 Bright
    Stop 
    }
}

ACTOR CBall : BaronBall
{
Speed 16
DamageType ice
FastSpeed 20
States
{
Spawn:
    BAL2 AB 1 Bright A_SpawnItemEx("CBallTrail",0,0,0,0,0,0,0,128,0)
    Loop
Death:
	TNT1 A 0
    TNT1 A 0 A_SpawnItemEx("BlueParticleSpawner", 0, 0, 0, 0, 0, 0, 0, 128)
		TNT1 AAA 0 A_CustomMissile("Kaboom6", 0, 0, random(0,360), 2, random(0,360))
		TNT1 AAAA 0 A_SpawnItemEx("IceDebris",0,0,0,Random(4,-4),Random(4,-4),Random(4,8),0,128)
		TNT1 AAA 0 Bright A_CustomMissile("Kaboom6", 0, 0, random(0,360), 2, random(0,360))	
    BAL2 CDE 3 Bright
    Stop
    }
}

ACTOR CBallTrail : BFG9500Trail
{
Scale 0.85
States
{
Spawn:
    TNT1 A 0
    TNT1 A 0 A_JumpIf(ACS_ExecuteWithResult(304) == 1, "Toaster")
	TNT1 A 1
    BAL2 AB 1 A_FadeOut(0.25)
    Goto Spawn+3
    }
}

ACTOR CryoComet : Comet
{
Scale 0.85
States
{
Spawn:
CRTT AAAABBBBCCCC 1 Bright A_SpawnItemEx("CryoCometTail",0,0,0,0,0,0,0,128)
Loop
Death:
TNT1 A 0 Bright A_Explode
TNT1 A 0 A_SpawnItemEx("BlueParticleSpawner", 0, 0, 0, 0, 0, 0, 0, 128)
CRTT DE 3 Bright
TNT1 A 0 A_SpawnItemEx("CryoCometDeath",0,0,0,0,0,0,0,128,0)
Stop
}
}

ACTOR CryoCometTail : CometTail
{
Scale 0.9
States
{
Spawn:
TNT1 A 0
TNT1 A 0 A_JumpIf(ACS_ExecuteWithResult(304) == 1, "Toaster")
TNT1 A 2
CRTT DEFGHI 2 Bright
Stop
}
}

ACTOR CryoCometDeath : CometDeath
{
States
{
Spawn:
TNT1 A 0
TNT1 AAA 0 A_CustomMissile("BlueKaboom", 0, 0, random(0,360), 2, random(0,360))	
TNT1 AAA 0 A_CustomMissile("SmokeFX2", 0, 0, random(0,360), 2, random(0,360))
CRTT JKLMN 3 Bright A_FadeOut(0.1)
Stop
}
}

ACTOR CIceSpikeSpawner
{
  Radius 5
  Height 5
  Speed 20
  FastSpeed 25
  Damage 0
  +RIPPER
  +FLOORHUGGER
  +BLOODLESSIMPACT
  +THRUSPECIES
  Species "Nobles"
  DamageType "NobleComet"
  Projectile
  MissileType MiniIceSpike
  Missileheight 0
  States
  {
  Spawn: 
    TNT1 AAAA 1 Bright A_CStaffMissileSlither
	TNT1 A 1 Bright A_MissileAttack
    Loop
  Death:  
    TNT1 A 1
    Stop
  }
}
ACTOR MiniIceSpike
{
  Radius 1
  Height 1
  Speed 0
  Damage 13
  Scale 0.5
  Projectile
  RenderStyle Add
  Alpha 0.9
  +NoClip
  +FloorHugger
  +DontHarmSpecies
  +Thruspecies
  +Ripper
  Species "Nobles"
  DamageType "NobleComet"
  SeeSound "Icespike" 
  States
  {
  Spawn:
    ICPL I 2 Bright
    ICPL H 2 Bright A_Explode(36,106,0)
    ICPL GFEDCBA 2 Bright
    Stop       
   }
}