ACTOR HellArchon : HellKnight 31340
{ 
Health 650
Speed 8 
PainChance 50
Mass 1000
Bloodcolor Red
Scale 1.05
Meleedamage 8
DropItem "LifeEssence" 120
DropItem "ArmorBonusMax" 120
DamageFactor "NobleComet", 0.0
DropItem "Gas" 70 60
Species "Nobles"
MONSTER 
+FLOORCLIP
+QUICKTORETALIATE
+MISSILEMORE
-BOSSDEATH
Obituary "%o was annihilated by a Hell Archon." 
HitObituary "The last thing %o saw was a Hell Archon's fist."
SeeSound "monster/ar2sit" 
ActiveSound "superbaron/act"
PainSound "superbaron/pain"
DeathSound "monster/ar2dth"
MeleeSound "baron/melee"
States 
{ 
Spawn: 
        HLAR A 10 Bright A_Look 
        Loop 
See: 
        HLAR AABB 3 Bright A_Chase
        HLAR B 0 Bright A_SpawnItem("HoofStep",0,0,0,0)
        HLAR CCDD 3 Bright A_Chase
        HLAR D 0 Bright A_SpawnItem("HoofStep",0,0,0,0)
        Loop
Missile:  
        TNT1 A 0 A_Jump(128,"Comet","FastBall")
	Normal:
        HLAR EF 6 Bright A_FaceTarget 
        HLAR G 0 Bright A_Custommissile ("HABall", 32, 0, 0) 
		HLAR G 0 Bright A_Custommissile ("HABall", 32, 0, 6)
		HLAR G 5 Bright A_Custommissile ("HABall", 32, 0, -6)
        HLAR IJ 6 Bright A_FaceTarget
        HLAR K 0 Bright A_Custommissile ("HABall", 32, 0, 0)
		HLAR K 0 Bright A_Custommissile ("HABall", 32, 0, 6)
		HLAR K 5 Bright A_Custommissile ("HABall", 32, 0, -6)
		TNT1 A 0 Bright A_Jump(87,"FastBall")
        Goto See
	FastBall:
        HLAR EF 5 Bright A_FaceTarget 
        HLAR G 0 Bright A_Custommissile ("RMArchonFastBall", 32, 0, 0)
		HLAR G 5 Bright A_Custommissile ("RMArchonFastBall", 32, 0, -6) 
        HLAR IJ 5 Bright A_FaceTarget
		HLAR K 0 Bright A_Custommissile ("RMArchonFastBall", 32, 0, 0) 
        HLAR K 5 Bright A_Custommissile ("RMArchonFastBall", 32, 0, -6)
		TNT1 A 0 Bright A_Jump(87,"Comet")
        Goto See
	Comet:
        HLAR MN 8 Bright A_FaceTarget 	
        HLAR O 7 Bright A_Custommissile ("HAComet", 32, 0, 0)		
		Goto See
Melee:
        HLAR EF 5 Bright A_FaceTarget 
        HLAR G 4 Bright A_MeleeAttack 
        HLAR FE 3 Bright A_FaceTarget 		
        Goto See
Pain: 
        HLAR Q 10 Bright A_Pain 
        Goto See 
Death: 
        HLAR R 8 Bright
        HLAR S 7 Bright A_Scream 
		TNT1 AAA 0 Bright A_SpawnItemEx("RedParticleSpawner", 0, 0, 40, 0, 0, 0, 0, 128) 
        HLAR U 5 Bright A_Fall 
        HLAR VW 5 Bright
		TNT1 AAAA 0 A_CustomMissile("SmokeFX", Random(30,60), 0, random(0,360), 2, random(0,360))			
    	HLAR X 4 Bright A_CustomMissile("HArchonSoul",86,0,0,2,90)
    	HLAR Z 4 Bright
        TNT1 A -1
	    Stop
Raise: 
        TNT1 A 0
	    TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
        HLAR ZYXWVUTSR 5 Bright 
        Goto See 
        } 
}

Actor HArchonSoul
{   
  Radius 1
  Height 1
  Speed 6
  Projectile
  RenderStyle Add
  Alpha 0.80
  States
  {
  Spawn:
    HASP ABCD 4 Bright
    Stop 
  }
}

ACTOR HABall : BaronBall
{
Translation "112:127=168:191"
Speed 16
FastSpeed 20
Damage 8
States
{
Spawn:
    BAL7 AB 1 Bright A_SpawnItemEx("HABallTrail",0,0,0,0,0,0,0,128,0)
    Loop
Death:
    TNT1 A 0 A_SpawnItemEx("RedParticleSpawner", 0, 0, 0, 0, 0, 0, 0, 128)
	TNT1 AAA 0 A_CustomMissile("Kaboom9", 0, 0, random(0,360), 2, random(0,360))
	TNT1 AAA 0 A_CustomMissile("SmokeFX4", 0, 0, random(0,360), 2, random(0,360))	
    BAL7 CDE 3 Bright
    Stop
    }
}

ACTOR HABallTrail : BFG9500Trail
{
Translation "112:127=168:191"
States
{
Spawn:
	TNT1 A 1
    BAL7 B 1 A_SetTranslucent(0.7,1)
    BAL7 A 1 A_SetTranslucent(0.6,1)
    BAL7 B 1 A_SetTranslucent(0.5,1)
    BAL7 A 1 A_SetTranslucent(0.4,1)
    BAL7 B 1 A_SetTranslucent(0.3,1)
    Stop
    }
}

ACTOR RMArchonFastBall : GuardianTracer
{
SeeSound "monsters/newfireshoot"
DeathSound "monsters/newfireexplode"
Decal RevenantScorch
Speed 18
FastSpeed 22
-SEEKERMISSILE
Translation "112:127=168:191"
States
{
Spawn:
	HAFB A 0 Bright A_BishopMissileWeave
    HAFB A 1 Bright A_SpawnItemEx("RMArchonFBTrail", 0, 0, 0, (0.1)*Random(4, 14), 0, (0.1)*Random(-4, 4), Random(-8, 8), 128)
	HAFB A 0 Bright A_BishopMissileWeave
    HAFB B 1 Bright A_SpawnItemEx("RMArchonFBTrail", 0, 0, 0, (0.1)*Random(4, 14), 0, (0.1)*Random(-4, 4), Random(-8, 8), 128)
	HAFB A 0 Bright A_BishopMissileWeave
    HAFB C 1 Bright A_SpawnItemEx("RMArchonFBTrail", 0, 0, 0, (0.1)*Random(4, 14), 0, (0.1)*Random(-4, 4), Random(-8, 8), 128)
    Loop
Death:
    TNT1 A 0 A_SpawnItemEx("RedParticleSpawner", 0, 0, 0, 0, 0, 0, 0, 128) 
	TNT1 AAA 0 A_CustomMissile("Kaboom9", 0, 0, random(0,360), 2, random(0,360))
	TNT1 AAA 0 A_CustomMissile("SmokeFX4", 0, 0, random(0,360), 2, random(0,360))	
    HAFB DEFG 3 Bright
    Stop
    }
}

ACTOR RMArchonFBTrail : MissileTrail
{
Scale 1
States
{
Spawn:
    TNT1 A 2
    HAFB ABCD 3 Bright A_FadeOut
    Stop
    }
}

ACTOR HAComet : Comet
{
Translation "112:127=168:191"
Scale 0.85
States
{
Spawn:
HCMT AAAABBBBCCCC 1 Bright A_SpawnItemEx("HACometTail",0,0,0,0,0,0,0,128)
Loop
Death:
TNT1 A 0 Bright A_Explode
TNT1 A 0 A_SpawnItemEx("RedParticleSpawner", 0, 0, 0, 0, 0, 0, 0, 128)
HCMT DE 3 Bright
TNT1 A 0 A_SpawnItemEx("HACometDeath",0,0,0,0,0,0,0,128,0)
Stop
}
}

ACTOR HACometTail : CometTail
{
Translation "112:127=168:191"
States
{
Spawn:
TNT1 A 2 Bright
HCMT DEFGHI 2 Bright
Stop
}
}

ACTOR HACometDeath : CometDeath
{
Translation "112:127=168:191"
States
{
Spawn:
TNT1 AAA 0 A_CustomMissile("Kaboom3", 0, 0, random(0,360), 2, random(0,360))
TNT1 AAA 0 A_CustomMissile("SmokeFX2", 0, 0, random(0,360), 2, random(0,360))
HCMT JKLMN 3 Bright A_FadeOut
Stop
}
}