ACTOR ImpLord : Imp 21768
{
	Health 400
	Speed 10
	Mass 500
	PainChance 30
	DropItem "LifeEssence" 100
	DropItem "ArmorBonusMax" 100
	DropItem "BerserkPack" 80
	DropItem "PureRage" 45
	DropItem "DemonAmmo" 100
    SeeSound "superimp/sight"
	PainSound "voidimp/pain"
	DeathSound "superimp/death"
	ActiveSound "superimp/active"
    MeleeSound "baron/melee"
	bloodcolor "DarkRed"
	RadiusDamageFactor 0.3
	+MissileMore
	+FloorClip
	+FastMelee
	+QUICKTORETALIATE
    Obituary "%o was smashed by an Imp Lord."
	HitObituary "%o was smashed by an Imp Lord."
	MeleeDamage 10
    States
    {
    Spawn:
        LROO A 10 A_Look
		LROI A 10 A_Look
        Loop
    See:
	    LROO AABB 3 A_Chase
	    TNT1 A 0 A_SpawnItem("HumanishStep",0,0,0,0)
	    LROO CCDD 3 A_Chase
	    TNT1 A 0 A_SpawnItem("HumanishStep",0,0,0,0)
        Loop	
     Missile:
	    TNT1 A 0 A_JumpIfCloser(250,"Claw")
        LROO EF 7 A_FaceTarget
        LROO G 5 A_CustomMissile("ImpLordBall",32,0,0)
        Goto See  
	 Claw:
	    LROO AA 7 A_FaceTarget
	    TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,1)
	    TNT1 A 0 ThrustThingZ(0,20,0,1)
	    LROO F 2 A_Recoil(-30)
	    LROO F 3 A_CustomMissile("ImpLunge",18,0,0,CMF_AIMDIRECTION)
		TNT1 A 0 A_PlaySound("baron/melee")
	    LROO F 6
	    LROO F 2 A_ScaleVelocity(0.2)
	    TNT1 A 0 A_ChangeFlag(SLIDESONWALLS,0)
	    LROO F 1 A_ScaleVelocity(0)
	   Goto See
     Melee:
        LROO EF 6 A_FaceTarget
        LROO G 4 A_MeleeAttack
        Goto See
     Pain:
        LROO H 2
        LROO H 2 A_Pain
        Goto See
    Death:
        LROO J 8 A_Scream
        LROO K 6
        LROO L 6 A_Fall
        LROO M -1
        Stop
    XDeath:
		LROO N 3 
		LROO O 3 A_XScream
		LROO P 3 A_SpawnItemEx("GibbedGenerator",0,0,0,0,0,0,0,128,0)
		LROO Q 3 A_Fall
		LROO RST 3
		LROO U -1
        Stop
    Raise:
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
        LROO TSRQPON 5
        Goto See
		}
}

ACTOR ImpLordBall : NewImpBall
{
  FastSpeed 30
  Speed 18
  Damage 7
}

Actor ImpLunge : PinkyLunge {Species "Imps"}