ACTOR ToxicLord : HellKnight 28528
{ 
Health 1125
PainChance 45
PainChance "Explosion", 60
Scale 1.15
BloodColor "Green"
MeleeDamage 15
DropItem "BossLifeEssence" 128 25
DropItem "BossArmorBonusMax" 128 1
DropItem "DemonAmmoBox" 128 200
DamageFactor "NobleComet", 0.0
Species "Nobles"
+MISSILEMORE
+FASTMELEE
+QUICKTORETALIATE
Obituary "%o was disintegrated by the toxins of the Toxic Lord." 
HitObituary "%o received a sweet hug from the Toxic Lord."
SeeSound "TLord/See"    
DeathSound "TLord/Death"  
PainSound "TLord/Pain"
MeleeSound "baron/melee"
Tag "\cdToxic Lord\c-"
States 
{ 
Spawn: 
        TNT1 A 0 A_SpawnItem("GHellionSmokeSpawner4",0,0,0,0)
        TLOD A 7 Bright A_Look
		TNT1 A 0 A_SpawnItem("GHellionSmokeSpawner4",0,0,0,0)
        TLOD A 7 Bright A_Look
		TNT1 A 0 A_SpawnItem("GHellionSmokeSpawner4",0,0,0,0)
        TLOI A 7 Bright A_Look
		TNT1 A 0 A_SpawnItem("GHellionSmokeSpawner4",0,0,0,0)
        TLOI A 7 Bright A_Look
        Loop 
See: 
        TNT1 A 0 A_SpawnItem("GHellionSmokeSpawner4",0,0,0,0)
        TNT1 A 0 A_SpawnItem("HoofStep",0,0,0,0)
        TLOD AA 3 Bright A_Chase
		TNT1 A 0 A_SpawnItem("GHellionSmokeSpawner4",0,0,0,0)
        TLOD BB 3 Bright A_Chase
        TNT1 A 0 A_SpawnItem("HoofStep",0,0,0,0)
		TNT1 A 0 A_SpawnItem("GHellionSmokeSpawner4",0,0,0,0)
        TLOD CC 3 Bright A_Chase
		TNT1 A 0 A_SpawnItem("GHellionSmokeSpawner4",0,0,0,0)
		TLOD DD 3 Bright A_Chase
        Loop
Missile:  
        TNT1 A 0 Bright A_Jump(128,"GiantBalls","BurstComet")
Normal:
        TLOD EF 6 Bright A_FaceTarget 
		TLOD G 1 Bright A_CustomMissile("PoisonBall", 42, 0, 0)		
		TNT1 A 0 A_CustomMissile("PoisonBall", 42, 0, -6)
		TLOD G 4 Bright A_CustomMissile("PoisonBall", 42, 0, 6)
        TLOD IJ 6 Bright A_FaceTarget 
		TLOD K 1 Bright A_CustomMissile("PoisonBall", 42, 0, 0)		
		TNT1 A 0 A_CustomMissile("PoisonBall", 42, 0, -6)
		TLOD K 4 Bright A_CustomMissile("PoisonBall", 42, 0, 6)		
		TNT1 A 0 A_Jump(87,"GiantBalls","BurstComet")
        Goto See
GiantBalls:
		TLOD EF 7 Bright A_FaceTarget
		TLOD G 6 Bright A_CustomMissile("DukeBall2", 32, 0, 0)
		TLOD IJ 7 Bright A_FaceTarget
		TLOD K 6 Bright A_CustomMissile("DukeBall2", 32, 0, 0)
		TNT1 A 0 A_Jump(87,"BurstComet")
		Goto See
BurstComet:
        TLO2 AB 8 Bright A_FaceTarget
        TLO2 C 2 Bright A_Custommissile("TLordComet",32,0,0)
		TNT1 A 0 A_Custommissile("TLordComet",32,0,-10)
		TLO2 C 5 Bright A_Custommissile("TLordComet",32,0,10)
        Goto See
Melee:
        TLO2 AB 7 Bright A_FaceTarget 
        TLO2 C 6 Bright A_MeleeAttack 	
        Goto See
Pain:
        TLOD N 4 Bright A_Pain
        Goto See
PainMissile:
		TLOD N 10 Bright A_Pain
        Goto Missile
    XDeath:
    Death: 
		TLOD O 7
		TLOD P 6 A_Scream 
		TLOD Q 5 A_Fall 	
		TLOD R 4 A_SpawnItem("BodyCrash",0,0,0,0)
		TLOD ST 4 A_SpawnItemEx("GreenGibbedGenerator",0,0,0,0,0,0,0,128,0)
		TLOD U -1 A_KillMaster
	    Stop
Raise: 
	    TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("VileHealEffect",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
		TLOD UTSRQPO 6
        Goto See 
        } 
}
actor PoisonBall : CStaffMissile
{
Radius 8
Height 12
damage 7
Speed 18
FastSpeed 22
Renderstyle Add
Alpha 0.90
PoisonDamage 15
Damagetype Poison
SeeSound "monsters/newfireshoot"
DeathSound "monsters/newfireexplode"
PROJECTILE
+EXPLODEONWATER
states
{
Spawn:
FVN1 A 1 Bright A_BishopMissileWeave
FVN1 A 0 Bright A_SpawnItemEx("PoisonTrail",0,0,0,0,0,0,0,0,10)
FVN1 B 1 Bright A_BishopMissileWeave
FVN1 B 0 Bright A_SpawnItemEx("PoisonTrail",0,0,0,0,0,0,0,0,10)
FVN1 C 1 Bright A_BishopMissileWeave
FVN1 C 0 Bright A_SpawnItemEx("PoisonTrail",0,0,0,0,0,0,0,0,10)
FVN1 D 1 Bright A_BishopMissileWeave
FVN1 D 0 Bright A_SpawnItemEx("PoisonTrail",0,0,0,0,0,0,0,0,10)
loop
Death:
TNT1 A 0 A_SpawnItemEx("GreenParticleSpawner", 0, 0, 0, 0, 0, 0, 0, 128)
TNT1 AAA 0 A_CustomMissile("Kaboom7", 0, 0, random(0,360), 2, random(0,360))
TNT1 AAA 0 A_CustomMissile("SmokeFX4", 0, 0, random(0,360), 2, random(0,360))
FVN1 EFGHIJ 3 Bright
stop
}
}



ACTOR Poisontrail
{   
   Radius 0
   Height 1
   PROJECTILE
   RENDERSTYLE ADD
   ALPHA 0.80
   States
   {
   Spawn:
      NULL A 1 Bright
      SSFX ABCDEFG 2 Bright
      Stop 
   }
}

ACTOR TLordComet : Comet
{
Damage 6
ExplosionDamage 42
DamageType "NobleComet"
MissileType ""
DeathSound "barbcomet/explosion"
States
{
Spawn:
BRTB AAABBB 1 Bright A_SpawnItemEx("BarbCometTail", 0, 0, 0, 0, 0, 0, 0, 128)
Loop
Death:
TNT1 A 0
TNT1 A 0 A_SpawnItemEx("GreenParticleSpawner", 0, 0, 0, 0, 0, 0, 0, 128)
TNT1 AAA 0 A_CustomMissile("SmokeFX2", 0, 0, random(0,360), 2, random(0,360))
TNT1 AAA 0 A_CustomMissile("Kaboom13", 0, 0, random(0,360), random(2,3), random(0,360))
BRTB C 3 Bright A_Explode
BRTB D 3 Bright A_SetTranslucent(0.75,1)
TNT1 AAAAA 0 A_SpawnItemEx("TLordPoison",0,0,10,Random(4,-4),Random(4,-4),Random(4,-2))
BRTB EFG 3 Bright
Stop
}
}

ACTOR GHellionSmokeSpawner4 : RedParticleSpawner
{
  States
  {
  Spawn:
    TNT1 A 0
    TNT1 AAA 0 A_SpawnItemEx("GHellionSmoke",random(12,-12),random(12,-12),random(12,64),0,0,random(1,3),0,128,0)
    TNT1 A 1
    Stop
  }
}

ACTOR GHellionSmoke4 : GHellionSmoke
{
Scale 0.6
}

Actor TLordPoison : BarbatosPoison 
{
DamageType "NobleComet"
}