ACTOR Beretta : Weapon
{
	Weapon.AmmoUse 1
	Weapon.AmmoGive 20
	Weapon.AmmoType "Clip"
	Obituary "%o was tickled by %k's pea shooter."
	+WEAPON.WIMPY_WEAPON
	Inventory.Pickupmessage "Picked up a pistol."
	
	Weapon.UpSound "w/load1"
	AttackSound "weapons/pistol"
	DamageType			MarineFire
	
	States
	{
		Ready:
		PISG A 1 A_WeaponReady
		goto Ready
		Deselect:
		PISG A 1 A_Lower
		PISG A 0 A_Lower
		goto Deselect
		Select:
		PISG A 1 A_Raise
		PISG A 0 A_Raise
		goto Select
		Fire:
		PISG A 1 A_GunFlash
		PISG A 0 A_FireCustomMissile("splatBulletCasing", 45 + random(-8,8), 0, 2, 3)
		PISG B 4 A_FireBullets (5.6, 0, 1, 9, "BulletPuff_Standard")	// damage increased from 5 to 9
		PISG C 2
		PISG B 3 A_ReFire
		Goto Ready
		Flash:
		PISF A 2 Bright A_Light1
		Goto LightDone
		PISF A 2 Bright A_Light0
		Goto LightDone
		Spawn:
		PIST A -1
		Stop
	}
}

ACTOR Beretta_Dual : Weapon
{
	Weapon.AmmoUse1 2
	Weapon.AmmoUse2 1
	Weapon.AmmoGive 20
	Weapon.AmmoType1 "Clip"
	Weapon.AmmoType2 "Clip"
	Obituary "%o was gunned down by %k's dual pistols."
	+WEAPON.WIMPY_WEAPON
	Inventory.Pickupmessage "Picked up 2 pistols."
	
	Weapon.UpSound "w/load1"
	AttackSound "weapons/pistol"
	DamageType			MarineFire
	
	States
	{
		Ready:
		DPIS A 1 A_WeaponReady
		goto Ready
		Deselect:
		DPIS A 1 A_Lower
		DPIS A 0 A_Lower
		goto Deselect
		Select:
		DPIS A 1 A_Raise
		DPIS A 0 A_Raise
		goto Select
		Fire:
		DPIS A 2 A_GunFlash
		DPIS B 1 bright  A_FireBullets (8, 8, 2, 9, "BulletPuff_Standard")	// damage increased from 5 to 9
		DPIS A 0 A_FireCustomMissile("splatBulletCasing", 45 + random(-8,8), 0, 2, 3)
		DPIS A 0 A_FireCustomMissile("splatBulletCasing", 45 + random(-8,8), 0, 2, 3)
		DPIS C 1
		DPIS B 3 A_ReFire
                goto Ready
		AltFire:
		DPIS A 2 A_GunFlash
		DPIS M 5 bright  A_FireBullets (4, 4, 1, 9, "BulletPuff_Standard")	// damage increased from 5 to 9
		DPIS A 0 A_FireCustomMissile("splatBulletCasing", 45 + random(-8,8), 0, 2, 3)
		DPIS N 5 bright  A_FireBullets (4, 4, 1, 5, "BulletPuff_Standard")
		DPIS A 0 A_FireCustomMissile("splatBulletCasing", 45 + random(-8,8), 0, 2, 3)
		DPIS B 3 A_ReFire
		Goto Ready
		Spawn:
		PIST A -1
		Stop
	}
}

ACTOR Beretta_SMG : Weapon
{
	Weapon.AmmoUse 1
	Weapon.AmmoGive 20
	Weapon.AmmoType "Clip"
	Obituary "%o was gunned down by %k's SMG."
	+WEAPON.WIMPY_WEAPON
	Inventory.Pickupmessage "Picked up an SMG."
	
	Weapon.UpSound "w/load1"
	AttackSound "weapons/pistol"
	DamageType			MarineFire
	
	States
	{
		Ready:
		SMGP A 1 A_WeaponReady
		goto Ready
		Deselect:
		SMGP A 1 A_Lower
		SMGP A 0 A_Lower
		goto Deselect
		Select:
		SMGP A 1 A_Raise
		SMGP A 0 A_Raise
		goto Select
		Fire:
		SMGP A 1
		SMGP B 2 bright  A_FireBullets (6, 0, 1, 14, "BulletPuff_Standard")	// damage increased from 6 to 10
		SMGP A 0 A_FireCustomMissile("splatBulletCasing", 45 + random(-8,8), 0, 2, 3)
		SMGP A 2 A_ReFire
		Goto Ready
		Spawn:
		PIST A -1
		Stop
	}
}