//Weapons used in Wolfenstein 3D

ACTOR WolfClip : Ammo 21049
{
	Inventory.PickupSound "pickups/ammo"
	Inventory.PickupMessage "Clip of Bullets"
	Inventory.Amount 8
	Inventory.MaxAmount 99
	Inventory.Icon "WCLIA0"
	Ammo.BackpackAmount 25
	Ammo.BackpackMaxAmount 99
	Mass 10000
	States
	{
	Spawn:
		WCLI A -1
		Loop
	}
}

ACTOR WolfClipDrop : WolfClip
{
	Inventory.Amount 4
}

ACTOR WolfClipBox : WolfClip 21072
{
	Inventory.PickupMessage "Box of Bullets"
	Inventory.Amount 25
	Inventory.Pickupsound "pickups/ammobox"
	Ammo.BackpackAmount 25
	States
	{
	Spawn:
		WAMM A -1
		Loop
	}
}

ACTOR WolfRocketPickup : Ammo
{
	Inventory.PickupSound "pickups/ammo"
	Inventory.PickupMessage "A Rocket"
	Inventory.Amount 1
	Inventory.MaxAmount 99
	Ammo.BackpackAmount 5
	Ammo.BackpackMaxAmount 99
	Mass 10000
	Scale 0.2
	States
	{
	Spawn:
		WROK A -1
		Loop
	}
}

ACTOR WolfRocketCrate : WolfRocketPickup 21073
{
	Inventory.PickupMessage "Crate of Rockets"
	Inventory.Amount 5
	Ammo.BackpackAmount 5
	Scale 0.2
}

ACTOR WolfGas : Ammo
{
	Inventory.PickupSound "pickups/ammo"
	Inventory.PickupMessage "Gas"
	Inventory.Amount 1
	Inventory.MaxAmount 99
	Ammo.BackpackAmount 14
	Ammo.BackpackMaxAmount 99
	Mass 10000
	Scale 0.2
	States
	{
	Spawn:
		WGAS A -1
		Loop
	}
}

ACTOR WolfGasCan : WolfGas 21074
{
	Inventory.PickupMessage "Canister of Gas"
	Inventory.Amount 14
	Ammo.BackpackAmount 14
}

ACTOR WolfKnife : Weapon
{
	Weapon.SelectionOrder 4
	Weapon.AmmoUse 0
	Weapon.YAdjust 17
	+Weapon.Wimpy_Weapon
	+Weapon.MeleeWeapon
	+Weapon.NoAlert
	AttackSound ""
	Obituary ""
	States
	{
	Ready:
		KNIF A 1 OFFSET (0, 17) 
			KNIF A 0 A_WeaponReady
		Loop
	Deselect:
		KNIF A 1 A_Lower
		Loop
	Select:
		KNIF A 1 A_Raise
		Loop
	Fire:
		KNIF B 3 OFFSET (0, 8)
		KNIF C 3 OFFSET (0, 17)
		KNIF D 3 OFFSET (0, 17) A_CustomPunch (ACS_ExecuteWithResult(800, 4), 1, 0, "BulletPuff")
			KNIF D 0 A_PlayWeaponSound ("weapons/wknife")
		KNIF E 3 OFFSET (0, 17)
			KNIF A 0  A_Refire
		Goto Ready
	Hold:
		KNIF A 1 OFFSET (0, 17)
			KNIF A 0 A_JumpIfInventory ("BotPlayer", 1, "DMHold")
		SPHold:
				KNIF A 0 A_Refire
			Goto Ready
		DMHold:
			KNIF B 3 OFFSET (0, 8)
			KNIF C 3 OFFSET (0, 17)
			KNIF D 3 OFFSET (0, 17) A_CustomPunch (ACS_ExecuteWithResult(800, 4), 1, 0, "BulletPuff")
				KNIF D 0 A_PlayWeaponSound ("weapons/wknife")
			KNIF E 3 OFFSET (0, 17)
		Goto SPHold
	}
} 


ACTOR WolfPistol : Weapon
{
	Weapon.SelectionOrder 3
	Inventory.PickupSound "pickups/ammo"
	Inventory.PickupMessage "Clip of Bullets"
	Weapon.AmmoType "WolfClip"
	Weapon.AmmoGive 8
	Weapon.AmmoUse 1
	Weapon.YAdjust 17
	+Weapon.Wimpy_Weapon
	AttackSound "weapons/wpistol"
	Obituary ""
	States
	{
	Spawn:
		WCLI A -1
		Loop
	Ready:
		LUGR A 1 OFFSET (0, 17)
			LUGR A 0 A_WeaponReady
		Loop
	Deselect:
		LUGR A 1 A_Lower
		Loop
	Select:
		LUGR A 1 A_Raise
		Loop
	Fire:
		LUGR B 2 OFFSET (0, 17)
		LUGR C 3 BRIGHT OFFSET (0, 17) A_FireBullets (2.0, 2.0, 1, ACS_ExecuteWithResult(800, 0) / 3)
		LUGR DE 3 OFFSET (0, 17) 
			LUGR C 0 A_Refire
		Goto Ready
	Hold:
		LUGR A 1 OFFSET (0, 17)
			LUGR A 0 A_JumpIfInventory ("BotPlayer", 1, "DMHold")
		SPHold:
				LUGR A 0 A_Refire
			Goto Ready
		DMHold:
			LUGR B 2 OFFSET (0, 17)
			LUGR C 3 BRIGHT OFFSET (0, 17) A_FireBullets (2.0, 2.0, 1, ACS_ExecuteWithResult(800, 0) / 3)
			LUGR DE 3 OFFSET (0, 17) 
			Goto SPHold
	}
}
 
ACTOR WolfMachineGun : Weapon 21050
{
	Weapon.SelectionOrder 2
	Inventory.PickupSound "pickups/mgun"
	Inventory.PickupMessage "Machine Gun"
	Weapon.AmmoType "WolfClip"
	Weapon.AmmoGive 6
	Weapon.AmmoUse 1
	Weapon.YAdjust 17
	AttackSound "weapons/wmachinegun"
	Obituary ""
	States
	{
	Spawn:
		MGUN P -1
		Loop
	Ready:
		MGUN A 1 OFFSET (0, 17)
			MGUN A 0 A_WeaponReady
		Loop
	Deselect:
		MGUN A 1 A_Lower
		Loop
	Select:
		MGUN A 1 A_Raise
		Loop
	Fire:
		MGUN AB 2 OFFSET (0, 17)
		MGUN C 3 BRIGHT OFFSET (0, 17) A_FireBullets (3.0, 3.0, 1, ACS_ExecuteWithResult(800, 0) / 3)
		MGUN D 3 OFFSET (0, 17)
			MGUN D 0 A_ReFire
		MGUN E 3 OFFSET (0, 17)
		Goto Ready
	Hold:
		MGUN C 3 BRIGHT OFFSET (0, 17) A_FireBullets (3.0, 3.0, 1, ACS_ExecuteWithResult(800, 0) / 3)
		MGUN D 3 OFFSET (0, 17)
			MGUN D 0 A_ReFire
		MGUN E 3 OFFSET (0, 17)
		Goto Ready
	}
} 

ACTOR WolfChaingun : Weapon 21051
{
	Weapon.SelectionOrder 1
	Inventory.PickupSound "pickups/cgun"
	Inventory.PickupMessage "Chaingun"
	Weapon.AmmoType "WolfClip"
	Weapon.AmmoGive 6
	Weapon.AmmoUse 1
	Weapon.YAdjust 17
	+Weapon.BFG
	AttackSound "weapons/wchaingun"
	Obituary ""
	States
	{
	Spawn:
		CGUN P -1
		Loop
	Ready:
		CGUN A 1 OFFSET (0, 17)
			CGUN A 0 A_WeaponReady
		Loop
	Deselect:
		CGUN A 1 A_Lower
		Loop
	Select:
		CGUN A 1 A_Raise
		Loop
	Fire:
		CGUN AB 2 OFFSET (0, 17)
		CGUN CD 3 BRIGHT OFFSET (0, 17) A_FireBullets (4.0, 4.0, 1, ACS_ExecuteWithResult(800, 0) / 3)
			CGUN D 0 A_ReFire
		CGUN E 2 OFFSET (0, 17)
		Goto Ready
	Hold:
		CGUN CD 3 BRIGHT OFFSET (0, 17) A_FireBullets (4.0, 4.0, 1, ACS_ExecuteWithResult(800, 0) / 3)
			CGUN D 0 A_ReFire
		CGUN E 2 OFFSET (0, 15)
		Goto Ready
	}
}

ACTOR WolfFlame : PlasmaBall
{
	Renderstyle Normal
	Alpha 1.0
	SeeSound "flame/fire"
	DeathSound ""
	Obituary ""
	States
	{
	Spawn:
		BAL3 AB 4
		Loop
	Death:
		BAL3 CDE 4
		Stop
	}
}

ACTOR WolfFlamethrower : Weapon 21075
{
	Weapon.SelectionOrder 1
	Inventory.PickupSound "pickups/ammo"
	Inventory.PickupMessage "Flame Thrower"
	Weapon.AmmoType "WolfGas"
	Weapon.AmmoGive 6
	Weapon.AmmoUse 1
	Weapon.YAdjust 17
	AttackSound "flame/fire"
	Obituary ""
	Scale 0.2
	States
	{
	Spawn:
		FLAM P -1
		Loop
	Ready:
		WFLM A 1 A_WeaponReady
		Loop
	Deselect:
		WFLM A 1 A_Lower
		Loop
	Select:
		WFLM A 1 A_Raise
		Loop
	Fire:
		WFLM B 2
		WFLM C 3 BRIGHT A_FireCustomMissile ("WolfFlame", 0, 1, 0, -8)
		WFLM D 2 A_ReFire
		Goto Ready
	Hold:
		WFLM B 2
		WFLM C 3 BRIGHT A_FireCustomMissile ("WolfFlame", 0, 1, 0, -8)
		WFLM D 2 A_ReFire
		Goto Ready
	}
} 

ACTOR WolfRocketPlayer : Rocket
{
	-ROCKETTRAIL
	SeeSound "missile/fire"
	DeathSound "missile/hit"
	Obituary ""
	States
	{
	Spawn:
		MISL A 1
		MISL A 1 BRIGHT A_CustomMissile ("WolfRocketSmoke", -40, 0, 0)
		Loop
	Death:
		BAL3 CDE 4 A_Explode
		Stop
	}
}


ACTOR WolfRocketLauncher : Weapon 21076
{
	Weapon.SelectionOrder 5
	Inventory.PickupSound "pickups/ammo"
	Inventory.PickupMessage "Rocket Launcher"
	Weapon.AmmoType "WolfRocketPickup"
	Weapon.AmmoGive 6
	Weapon.AmmoUse 1
	Weapon.YAdjust 17
	+WEAPON.EXPLOSIVE
	AttackSound "flame/fire"
	Obituary ""
	Scale 0.2
	States
	{
	Spawn:
		WROC P -1
		Loop
	Ready:
		WROC A 1 A_WeaponReady
		Loop
	Deselect:
		WROC A 1 A_Lower
		Loop
	Select:
		WROC A 1 A_Raise
		Loop
	Fire:
		WROC B 3
		WROC B 2 BRIGHT A_FireCustomMissile ("WolfRocketPlayer", 0, 1, 0, -8)
		WROC C 10
		WROC D 25
		WROC D 5 A_ReFire
		Goto Ready
	Hold:
		WROC B 5
		WROC C 10 BRIGHT A_FireCustomMissile ("WolfRocketPlayer", 0, 1, 0, -8)
		WROC D 25
		WROC D 5 A_ReFire
		Goto Ready
	}
}